Hallo,

Grundlage meines Problems ist, dass ich die Systemzeit der SIMOTION per Profibus ausgeben, bzw. setzen möchte. Das Ausgeben & Setzen der Systemzeit als ST-Quellcode unter Verwendung des System-Funktionsblocks "RTC" funktioniert bereits. Als Ausgabeformat erhalte ich dann den Datentyp DT bzw. DATE & TOD (über die Konvertierungsfunktionen DT_TO_xxxx). Um diese Werte dann per Profibus übertragen zu können, müssen diese mir aber in einem Format wie (U)INT, D(U)INT, WORD oder DWORD vorliegen. So hätte ich dann auch noch die Chance die Werte entsprechend zu konvertieren und auf die Gegenseite anzupassen. Soweit ich weiß werden intern DATE und TOD sogar als DINT behandelt, aber bei jeglichen Konvertierungsversuchen meinerseits gabs Gemecker vom Compiler. Habt ihr eine Idee? Ein bitweiser Zugriff würde im Notfall auch helfen.

Vielen Dank!

Gruß, Daniel

Ich benötige sowohl die Uhrzeit, als auch das Datum. Mit welchem Trick wandel ich denn TOD in TIME um?

Gruß, Daniel

Danke Christoph, das könnte genau das sein  was ich suche. Werde ich morgen mal ausprobieren.

Bei Beckhoff TwinCAT ST gab es die Möglichkeit so etwas direkt über Pointer zu lösen. Also einfach den Adressbereich der Variablen A in den Adressbereich der Variablen B mit gleicher Größe kopieren. Deine Lösung ähnelt glaube ich diesem Vorgehen. Ist es denn möglich in SIMOTION ST Pointer vernünftig zu nutzen und falls ja, existieren hierfür auch gängigen Funktionen wie MEMCPY, MEMSET, MEMCMP etc.?

Gruß, Daniel

Christoph, dein Vorschlag hat wunderbar funktioniert. Habe mir jetzt zwei Funktionsbausteine geschrieben: Der eine splittet das TOD Format auf und der andere setzt aus den aufgesplitteten Größen das TOD Format zusammen.

Den Quelltext habe ich angehangen, vielleicht hilft das ja dem einen oder anderen in der Zukunft, wenn er über diesen Beitrag stolpert. Ähnlich könnte man mit dem Datum verfahren, allerdings müsste man hier mit einem sog. gregorianischen Algorithmus rechnen. Oder gibt es hier schon was fertiges für die SIMOTION?

INTERFACE

   FUNCTION_BLOCK FB_GET_SPLIT_TOD;
   FUNCTION_BLOCK FB_SET_SPLIT_TOD;

END_INTERFACE

IMPLEMENTATION
   
    FUNCTION_BLOCK FB_GET_SPLIT_TOD

    VAR_INPUT                    //declaration of input parameters
       tdIn          : TOD;          //TOD input
    END_VAR

    VAR_OUTPUT                   //declaration of output parameters
        uiHours      : UINT;         //hours from tdIn
        uiMinutes    : UINT;         //minutes from tdIn
        uiSeconds    : UINT;         //seconds from tdIn
        uiMseconds   : UINT;         //miliseconds from tdIn
    END_VAR

    VAR                          //declaration of local variables
        nTod         : UDINT;       //TOD input as UDINT
        arbTemp      : ARRAY[0..3] OF BYTE;   //32 bit for temp data
    END_VAR

        //convert TOD to UDINT
        arbTemp      := ANYTYPE_TO_LITTLEBYTEARRAY(tdIn, 0);
        nTod         := LITTLEBYTEARRAY_TO_ANYTYPE(arbTemp, 0);

        //splitting milliseconds into h, m & s
        uiHours      := UDINT_TO_UINT(  nTod / (60*60*1000) );
        uiMinutes    := UDINT_TO_UINT( (nTod MOD (60*60*1000)) / (60*1000) );
        uiSeconds    := UDINT_TO_UINT( (nTod MOD (60*1000)) / (1000) );
        uiMseconds   := UDINT_TO_UINT(  nTod MOD 1000 );
    END_FUNCTION_BLOCK

    FUNCTION_BLOCK FB_SET_SPLIT_TOD

    VAR_INPUT                   //declaration of input parameters
        uiHours      : UINT;        //hours from tdIn
        uiMinutes    : UINT;        //minutes from tdIn
        uiSeconds    : UINT;        //seconds from tdIn
        uiMseconds   : UINT;        //miliseconds from tdIn
    END_VAR

    VAR_OUTPUT                  //declaration of output parameters
        tdOut        : TOD;         //TOD output
    END_VAR

    VAR                         //declaration of local variables
        nTod        : UDINT;        //TOD input as UDINT
        arbTemp     : ARRAY[0..3] OF BYTE;    //32 bit for temp data
    END_VAR

        //adding milliseconds from h, m, & s
        nTod        :=        UINT_TO_UDINT(uiHours) * 60*60*1000;
        nTod        := nTod + UINT_TO_UDINT(uiMinutes) * 60*1000;
        nTod        := nTod + UINT_TO_UDINT(uiSeconds) * 1000;
        nTod        := nTod + UINT_TO_UDINT(uiMseconds);

        //convert UDINT to TOD
        arbTemp      := ANYTYPE_TO_LITTLEBYTEARRAY(nTod, 0);
        tdOut        := LITTLEBYTEARRAY_TO_ANYTYPE(arbTemp, 0);

    END_FUNCTION_BLOCK

END_IMPLEMENTATION

Nun habe ich auch eine Lösung für das Datumsformat gefunden. Basieren tut das ganze auf dem Algorithmus von Gary Katch (1999):

http://alcor.concordia.ca/~gpkatch/gdate-algorithm.html

http://alcor.concordia.ca/~gpkatch/gdate-method.html

Angehangen habe ich eine ST-Quelldatei, in welcher die folgenden Funktionen für die SIMOTION implementiert sind:

• Zusammenführen vom DATE  Format und TOD Format zum DT (DATE_AND_TIME) Format
• Aufteilen des DT (DATE_AND_TIME) Format zum DATE  Format und TOD Format
• Umwandlung von Stunden, Minuten, Sekunden und Millisekunden ins TOD-Format und umgekehrt
• Umwandlung von Jahren, Monaten und Tagen ins DATE Format und umgekehrt

Mit entsprechenden Programmierkenntnissen lassen sich diese Funktionen auch in andere Programmiersprachen "konvertieren". Feedback ist natürlich immer erwünscht :)

Gruß, Daniel