Batteriestatus abfragen

Hallo Morten,
danke für den goldenen Tip. Ich lese die Batteriepufferung direkt (s. Hilfe zum SFC51).

Gruß Andreas

Anbei die AWL-Quelle:
Jede Stunde bzw. mit einem Quittierungsimpuls wird der Status ausgelesen.


DATA_BLOCK DB 194
TITLE =
VERSION : 0.1

STRUCT
REQ : BOOL ;//Anfrage starten
BUSY : BOOL ;
RetVAl : INT ;
count : STRUCT
soll : INT := 3600;//in sec
ist : INT ;
END_STRUCT ;
Come : ARRAY [1 .. 20 ] OF BYTE ;
END_STRUCT ;
BEGIN
REQ := FALSE;
BUSY := FALSE;
RetVAl := 0;
count.soll := 3600;
count.ist := 0;
Come[1] := B#16#0;
Come[2] := B#16#0;
Come[3] := B#16#0;
Come[4] := B#16#0;
Come[5] := B#16#0;
Come[6] := B#16#0;
Come[7] := B#16#0;
Come[8] := B#16#0;
Come[9] := B#16#0;
Come[10] := B#16#0;
Come[11] := B#16#0;
Come[12] := B#16#0;
Come[13] := B#16#0;
Come[14] := B#16#0;
Come[15] := B#16#0;
Come[16] := B#16#0;
Come[17] := B#16#0;
Come[18] := B#16#0;
Come[19] := B#16#0;
Come[20] := B#16#0;
END_DATA_BLOCK

FUNCTION FC 194 : VOID
TITLE =
VERSION : 0.1

VAR_TEMP
SZL_HEADER : STRUCT
LENTHDR : WORD ;
N_DR : WORD ;
END_STRUCT ;
END_VAR
BEGIN
NETWORK
TITLE =Anfrage starten

U DB194.DBX 0.0;
R DB194.DBX 0.0;

O M 60.4; // Quittierungsimpuls
SPB read;

O( ;
L DB194.DBW 4; // Sollwert = 0
L 0; // keine Abfrage
==I ;
) ;
ON M 2.5; // Sekundenimpuls
UN DB194.DBX 0.1;
BEB ;
L DB194.DBW 6;
+ 1;
T DB194.DBW 6;

L DB194.DBW 4;
L DB194.DBW 6;
>I ;
BEB ;
read: NOP 0;
S DB194.DBX 0.0;
L 0;
T DB194.DBW 6;

L 8; // Länge in Worten
T #SZL_HEADER.LENTHDR;
L 1; // einen Datensatz lesen
T #SZL_HEADER.N_DR;

CALL SFC 51 (
REQ := DB194.DBX 0.0,
SZL_ID := W#16#392,// Batteriestatus
INDEX := W#16#0,// Index 0 für CPU
RET_VAL := DB194.DBW 2,
BUSY := DB194.DBX 0.1,
SZL_HEADER := #SZL_HEADER,
DR := DB194.Come);

END_FUNCTION