HID tags scripts WinCC

Hello all,

In our project we use PCS7 and sometimes they've made HMI tags using HID. Which means the tags sometimes consist of following format: HierarchyFolder/CFC/BlockName.IO

Now when we move these CFCs the HierarchyFolder will change as will the tagname. Now when these tags are undefined in scripting using WinCC they will not automatically change to the new hierarchy folder.

This is why we would like to open scripts find tags that consist of followin format:

HierarchyFolder/CFC/BlockName.IO

and change these tags to

CFC/BlockName.IO

This way we can turn off HID tags everywhere & compile so no more tags use HierarhcyFolder in their name. After this we can move CFCs as much as we like.

Thanks to Harry ji we can already export these scripts into a notepad file but now we would like to change them. Can any1 help us maybe editing this script? Or pointing us in the right direction?

Link to Harry ji's script: https://support.industry.siemens.com/tf/ww/en/posts/tool-to-export-all-scripts-in-a-pdl-to-notepad/118180?page=1&pageSize=10

Thanks in advance!

Hello Harry,

First of all thank you for your script it works perfectly but we have a small problem. The tags don't consist of the name "HierarhcyFolder" all the time.

For example we have tags named "Drain/M5000/Motor.Q" should be named M5000/Motor.Q

When other tags are named like "Fill/Valves/V5050/VALVE.Q" -> "V5050/VALVE.Q".

I've tried editing your script but no succes. I'm looking for a script that automatically searches for tags.

Usually tags are placed between brackets -> "Tag"

The script would have to look for everything between brackets and then look if there are more than 1 slashes -> /

If there is more than one "/" it should only keep the CFCname/blockname.io.

For example:

GetTagBit("Drain/Motors/M5000/Motor.Q");

It should save "Drain/Motors/M5000/Motor.Q" and look if it has more than one "/"

In this case it is true.

It should now change the tag to:

GetTagBit("M5000/Motor.Q");

---------------------------------------

If you could write anything for this we would be helped so much we could use this for so many clients.

Thanks in advance!

Hello Harry,

For my next projects I've used your other tool to export all scripts to a textfile.

I then used a self-made script to look for the words "gettag, settag,..." to print those lines. in the textfile to another textfile.

I now have all scripts used in the project and in some of those projects it's not looking to good. (400+ undefined scripts used).

While I now have a list of undefined tags I think I can use the script you've made right now to replace those.

But I think this will take a lot of time for the script to run because it will search for 400+ HID tags in every script to replace them.

This is a good workaround though but if you could make anything that automatically does this it would help us so much.

But I do understand that you're busy and you've helped us alot already!

We would like to thank you again for your help already!

Regards.

Here is a more generic script to search all scripts in the process graphics (those not with leading "@" signs) and remove all hierarchy folders from the tags referenced in the scripts.  To use this script within Graphics Designer, make sure to go to Tools - References... and include Microsoft Scripting Runtime.  Be advised that scripts on object properties may have tag triggers, this VB script does not account for fixing the tag triggers.  You will have to add additional code to do that.

Sub ReplaceTags()
    Dim FSO As New FileSystemObject  ' Requires Reference: Microsoft Scripting Runtime
    Dim Folder As Folder             ' Requires Reference: Microsoft Scripting Runtime
    Dim File As File                 ' Requires Reference: Microsoft Scripting Runtime
    Dim Doc As Document
    Dim Obj As HMIObject
    Dim Prop As HMIProperty
    Dim Evt As HMIEvent
   
    Set Folder = FSO.GetFolder(grafexe.ApplicationDataPath)
   
    For Each File In Folder.Files
        If Not Left(File.Name, 1) = "@" And Right(LCase(File.Name), 4) = ".pdl" Then
            Set Doc = grafexe.Documents.Open(File.Path)
            DocChanged = False
   
            For Each Obj In Doc.HMIObjects
                If Not Obj.Type = "HMIActiveXControl" Then  ' ActiveX Controls do not like the "For Each Evt" or the "For Each Prop" looping constructs 
                    For Each Evt In Obj.Events
                        If Evt.Actions.Count > 0 Then
                            If Evt.Actions(1).ActionType = hmiActionTypeScript Then ' this checks mouse events
                                DocChanged = DocChanged Or CheckScript(Evt.Actions(1))
                            End If
                        End If
                    Next
                    For Each Prop In Obj.Properties
                        If Prop.DynamicStateType = hmiDynamicStateTypeScript Then ' this checks property scripts
                            DocChanged = DocChanged Or CheckScript(Prop.Dynamic)
                        End If
                        For Each Evt In Prop.Events
                            If Evt.Actions.Count > 0 Then
                                If Evt.Actions(1).ActionType = hmiActionTypeScript Then ' this checks property data change events
                                    DocChanged = DocChanged Or CheckScript(Evt.Actions(1))
                                End If
                            End If
                        Next
                    Next
                End If
            Next
           
            If DocChanged Then Doc.Save
            Doc.Close
        End If
    Next
End Sub

Function CheckScript(Scr As HMIScriptInfo) As Boolean
    OldCode = Left(Scr.SourceCode, Len(Scr.SourceCode) - 2) ' chop off the trailing extra carriage return
    NewCode = OldCode
    CharPos = InStr(1, NewCode, """") ' find an item in the script between quotes
    While CharPos > 0
        HierarchyFolderFound = False
        CharPos2 = InStr(CharPos + 1, NewCode, """") ' find the close quotes
        BetweenQuotes = Mid(NewCode, CharPos + 1, CharPos2 - CharPos - 1)
        CharPos3 = InStr(1, BetweenQuotes, "/")  ' is this a PCS7 tag?
        If CharPos3 > 0 Then
            CharPos4 = InStr(CharPos3 + 1, BetweenQuotes, "/")  ' is there more than one slash?
            If CharPos4 > 0 Then             ' we have a hierarchy folder to remove
                NewCode = Replace(NewCode, """" & Left(BetweenQuotes, CharPos3), """")
                HierarchyFolderFound = True
            End If
        End If
        If not HierarchyFolderFound Then  ' move on to the next item in quotes
            CharPos = InStr(CharPos2 + 1, NewCode, """")
        End If
    Wend
    If Not (NewCode = OldCode) Then
        CheckScript = True        ' mark the graphic as changed
        Scr.SourceCode = NewCode  ' apply the modified code
    Else
        CheckScript = False
    End If
End Function

Regards

David Hochhauser

New question published by AlexSinitsin is split to a separate thread with the subject HID tags scripts WinCC TIA.

Best regards
Jen_Moderator