Compare Previous scan value in SCL

ercag

Hi Everybody;

What I wanna do in SCL is this;

Compare previous Scan value and new value.If the new value is different than previous value than give an alarm.But the trick point is I wanna use alarm_8p SD1 and SD 2 inputs to show the old value and the new value on the scada.

ALARM8P(EN_R := TRUE // IN: BOOL
,SIG_1 := OUT
,SD_1 :=
,SD_2 :=

How can I do that?
Thanks to all.For your helps.

Have a nice year.

VAR_INPUT
BOOL_IN_VALUE {S7_qc:='true';
S7_dynamic:='true';
S7_m_c:='true'} : BOOL := 0; // Current Bool input value
REAL_IN_VALUE {S7_qc:='true';
S7_dynamic:='true';
S7_m_c:='true'} : REAL := 0.0; // Current Real input value
SAMPLE_T {S7_visible:='false';
S7_sampletime:='true'} : REAL := 1; // Sample Time [s]
MSG_EVID {S7_visible:='false';
S7_link:='false';
S7_param :='false';
S7_server:='alarm_archiv';
S7_a_type:='alarm_8p'} : DWORD := 0; // Message ID
BA_EN {S7_visible:='false';
S7_m_c:='true'} : BOOL := 0; // Batch Enable
OCCUPIED {S7_visible:='false';
S7_m_c:='true'} : BOOL := 0; // Occupied by Batch
BA_ID {S7_visible:='false';
S7_m_c:='true'} : DWORD := 0; // Batch ID
BA_NA {S7_visible:='false';
S7_m_c:='true'} : STRING[32] := ''; // Batch Name
STEP_NO {S7_visible:='false';
S7_m_c:='true'} : DWORD := 0; // Batch Step Number
RUNUPCYC {S7_visible:='false';
S7_link:='false'} : INT := 3; // Lag: Number of Run Up Cycles
END_VAR

VAR_IN_OUT
AUX_PR08 {S7_visible:='false'} : ANY; // Auxiliary Value 8
AUX_PR09 {S7_visible:='false'} : ANY; // Auxiliary Value 9
AUX_PR10 {S7_visible:='false'} : ANY; // Auxiliary Value 10
END_VAR

VAR_OUTPUT
QBOOL_OLD_VALUE {S7_qc:='true';
S7_dynamic:='true';
S7_m_c:='true'} : BOOL := 0; // Previous Bool input value
QREAL_OLD_VALUE {S7_qc:='true';
S7_dynamic:='true';
S7_m_c:='true'} : REAL := 0.0; // Previous Real input value
QMSG_ERR {S7_visible:='false';
S7_dynamic:='true'} : BOOL := 0; // 1=Message ERROR
QMSG_SUP {S7_visible:='false';
S7_dynamic:='true';
S7_m_c:='true'} : BOOL := 0; // 1=Message Suppression Active
MSG_STAT {S7_visible:='false';
S7_dynamic:='true'} : WORD := 0; // Message: STATUS Output
MSG_ACK {S7_visible:='false';
S7_dynamic:='true'} : WORD := 0; // Message: ACK_STATE-output
QERR {S7_visible:='false';
S7_m_c:='true'} : BOOL := 1; // 1=Error
END_VAR

// Static variables
VAR
ALARM_8P_1 : ALARM_8P; // Multi-instanced ALARM_8P
siBA_ID : DWORD := 0; // Old value BA_ID
sbyBA_NA : ARRAY[1..32] OF BYTE := 32(0);
STEP_NO_LOC : DWORD; // Local variable, into which the STEP_NO input is copied.
BA_ID_LOC : DWORD; // Local variable, into which the BA_ID input is copied.
END_VAR

// Temporary variables
VAR_TEMP
ERR : INT; // Startup error
END_VAR

BEGIN
//Resave STEP_NO as STEP_NO_LOC und resave BA_ID as BA_ID_LOC
STEP_NO_LOC := STEP_NO; // Resave, due to output of STEP_NO_LOC in ALARM_8P
BA_ID_LOC := BA_ID; // Resave, due to output of BA_ID_LOC in ALARM_8P
IF siBA_ID <> BA_ID_LOC THEN
// STRING variables may not be interconnected to ALARM8_P as auxiliary
// process values, therefore transferred in ARRAY OF BYTE.
FOR ERR := 1 TO 32
DO
sbyBA_NA[ERR] := 0; // Delete array as default
END_FOR;
ERR := BLKMOV (SRCBLK:= BA_NA,DSTBLK:=sbyBA_NA);
siBA_ID := BA_ID_LOC; // Save modified BA_ID
END_IF;

// Call up ALARM_8P with lock logic (MSG_LOCK)
ALARM_8P_1( EN_R := TRUE, // Update the ACKL_STATE output
ID := 16#EEEE, // PMC communication channel
EV_ID:= MSG_EVID,
SIG_1:= QBOOL_OLD_VALUE <> BOOL_IN_VALUE,
SIG_2:= QREAL_OLD_VALUE <> REAL_IN_VALUE,
SIG_3:= 0,
SIG_4:= 0,
SIG_5:= 0,
SIG_6:= 0,
SIG_7:= 0,
SIG_8:= 0,
SD_1 := sbyBA_NA,
SD_2 := STEP_NO_LOC,
SD_3 := BA_ID_LOC,
SD_4 := QBOOL_OLD_VALUE,
SD_5 := BOOL_IN_VALUE,
SD_6 := QREAL_OLD_VALUE,
SD_7 := REAL_IN_VALUE ,
SD_8 := AUX_PR08,
SD_9 := AUX_PR09,
SD_10 := AUX_PR10);
QMSG_ERR := ALARM_8P_1.ERROR;
MSG_STAT := ALARM_8P_1.STATUS;
MSG_ACK := ALARM_8P_1.ACK_STATE;
END_IF;
IF (MSG_STAT = 21) THEN // Block locked
QMSG_SUP := TRUE;
ELSE
QMSG_SUP := FALSE;
END_IF;
QBOOL_OLD_VALUE := BOOL_IN_VALUE ; // Previous Bool input value
QREAL_OLD_VALUE := REAL_IN_VALUE ; // Previous Real input value

QERR := NOT OK; // Note negated OK-Flag result in the block

END_FUNCTION_BLOCK



Hope this helps,
David