Hello,

I've already tried a million things... I just want to be able to use BLKMOV for writing the content of a DB into some Qs I have, IN SCL. I'm using Step 7 V5.7 for an S7-400H.

In context, I have a PNPN coupler with inputs and outputs configured, and I need to be able to input/output some data I may have in DB200. In LAD it worked perfectly, I have the DB as symbolic address, which is easy and fine, and then I can write the destination (DSTBLK from BLKMOV I mean) just as a pointer like P#Q384.0 BYTE 6. In SCL I already knew I couldn't use this pointer and needed to creat an ANY pointer by creating a STRUCT and some tweaks, I manage to find that memory area of Q is hex code 16#82, but couldn't manage to make it work at all.

This code was:

FUNCTION FC211 : VOID
TITLE = 'PNPN_DATA_TRANSFER'
AUTHOR : 'FGT'
VERSION : '1.0'

VAR_TEMP
    // Temporary Variables
    myPointerStruct : STRUCT
        ANY_ID : BYTE;
        DataType : BYTE;
        COUNT: WORD;
        DB_NUM: WORD;
        AREA: BYTE;
        BYTE_POINTER: DWORD;
    END_STRUCT;
    myPointer AT myPointerStruct: ANY;
    MOV_ERROR : INT;
END_VAR

VAR
    // Static Variables
END_VAR

BEGIN
    myPointerStruct.ANY_ID := B#16#10; //Hex for the syntax ID
    myPointerStruct.DataType := B#16#02; //HEX for the data type Byte
    myPointerStruct.COUNT := INT_TO_WORD(6); // 6 bytes
    myPointerStruct.DB_NUM := 0;
    myPointerStruct.AREA := B#16#82; // CODE FOR MEMORY AREA Q
    myPointerStruct.BYTE_POINTER := 16#000C00; //384 AS BIT ADDRESS

    MOV_ERROR := BLKMOV(SRCBLK := "Siemens_CFDx_FDM_DB".FCC_DATE_TIME // IN: ANY
           ,DSTBLK := myPointer // OUT: ANY
           ); // INT               
END_FUNCTION

So I tried different things, I found a Siemens entry mentioning that in SCL we can use QB384, and it worked this way but only for the first BYTE, it didn't recognise that I have 6 Bytes as Source because Destination is just 1 Byte...

I tried iterations of all this, of the any pointer struct and I don't know, too many things hahahaha

I'm confident the pointer should work, I must just have used it wrong in:

myPointerStruct : STRUCT
        ANY_ID : BYTE;
        DataType : BYTE;
        COUNT: WORD;
        DB_NUM: WORD;
        AREA: BYTE;
        BYTE_POINTER: DWORD;
    END_STRUCT;
    myPointer AT myPointerStruct: ANY;

myPointerStruct.ANY_ID := B#16#10; //Hex for the syntax ID
    myPointerStruct.DataType := B#16#02; //HEX for the data type Byte
    myPointerStruct.COUNT := INT_TO_WORD(6); // 6 bytes
    myPointerStruct.DB_NUM := 0;
    myPointerStruct.AREA := B#16#82; // CODE FOR MEMORY AREA Q
    myPointerStruct.BYTE_POINTER := 16#000C00; //384 AS BIT ADDRESS

Help me please, I'm desperate hahaha SCL and pointers make me crazy tbh.

Also, I call this FC in a Chart. The point here is "I'm not allowed" to use LAD, long story short: we must program Functions in SCL and call them in a Chart.

I mean, programming in SCL in Step 7 V5.7 doesn't “allow” this kind of pointers, I already tried and the compiler doesn't like it.

I found Forum entries and siemens support entries talking about it. Such as “How can you construct an ANY pointer in S7-SCL using the AT function? - ID: 21946854 - Industry Support Siemens”.

I also simplified my problem in just “one use” let's say, but I basically need to create a function where I read/write multiple addresses seaparately. For example, I was talking about needing to read 6 bytes from an array in a DB and writing them in an output (6 outputs of 1 Byte each). But in the same function I will also need to read other arrays with different lengths (6, 24, 1, 150…) and write them into their respective outputs. This is why I would like to be able to use BLKMOV in a way where I say “start in byte 0 and end in byte 50” for example.

Don't know if I made myself clear haha thanks for the quick reply! 

I already solved the issue!! Thanks for the reply anyway.

For anyone who this might help, the solution is to deeply understand how to make an ANY Pointer, it wasn't completely clear to me until now.

With Manual "https://support.industry.siemens.com/cs/de/en/view/18652056", in Apendix section A.3.4.5 there's a helpful figure about the elements of the pointer.

I managed to understand that if I want to write in this case in QB384.0, that means the byte address is 384(byte)*8(bits)=3072 which in Hex is C00 so I did:

VAR_TEMP
    myPointerStruct : STRUCT
        ANY_ID : BYTE;
        DataType : BYTE;
        COUNT: WORD;
        DB_NUM: WORD;
        AREA: BYTE;
        BYTE7: BYTE;
        BYTE_POINTER: WORD;
    END_STRUCT;
    myPointer AT myPointerStruct: ANY;
    DONE : INT;

END_VAR

VAR_OUTPUT
    OUT_DATETIME: ANY;

END_VAR

BEGIN

    myPointerStruct.ANY_ID := B#16#10; //Hex for the syntax ID
    myPointerStruct.DataType := B#16#02; //HEX for the data type Byte
    myPointerStruct.COUNT := INT_TO_WORD(6); // 6 bytes
    myPointerStruct.DB_NUM := 0; //DB number, 0 for no DB address
    myPointerStruct.AREA := B#16#82; // CODE FOR MEMORY AREA type Q
    myPointerStruct.BYTE7 := 0;
    myPointerStruct.BYTE_POINTER := w#16#0C00; //384 AS BIT ADDRESS

    DONE := BLKMOV(SRCBLK := "Siemens_CFDx_FDM_DB".FCC_DATE_TIME // IN: ANY
           ,DSTBLK := myPointer // OUT: ANY
           ); // INT

This way I managed to create in SCL an any pointer that's basically "P#Q384.0 BYTE 6".

But! Important to mention that this does only work for Q384, it's not standard because I'm setting Byte 7 as 0, but Byte 7 contains 3 bits about the Byte address (as you can see in the previous figure), which I don't need for 384-->0C00, but it may be needed for higher Byte addresses.

myPointerStruct : STRUCT         
ANY_ID : BYTE;         
DataType : BYTE;         
COUNT: WORD;         
DB_NUM: WORD;         
AREA: BYTE;         
BYTE_POINTER: DWORD;     
END_STRUCT;     
myPointer AT myPointerStruct: ANY;

myPointerStruct.BYTE_POINTER := SHL(in:= INT_TO_DWORD(StartAddress),n:=3) OR 16#82000000;​