Procedure to convert PROFINET device names

7/3/2023 4:37 PM	Rate (0)
Micah Lindstrom Regular Member Joined: 1/11/2018 Last visit: 6/30/2025 Posts: 13 Rating: (1)	How do I manually convert non-compliant PROFINET device names? Per multiple help docs it is clear to me the requirements for PROFINET device names which do not need to be converted. For example, st36000mio01 does not need to be converted, it is already compliant. But when a name does need to be converted, it is not clear to me how that is done. For example st36000_mio01 does need to be converted, and TIA Portal automatically converts it to st36000xbmio01f894. It appears underscores are always converted to xb and plus signs are always converted to xn. But where does the final f894 come from? There is a different suffix after every converted name and I do not know what that should be. Relevant info which convers compliant names -- but do not cover the conversion for non-compliant names. SIOS 109479552 FAQ What are the rules for PROFINET device names in PROFINET specification V2.3 in STEP 7 V5 und TIA Portal? SIOS 109815056 / 161014450571 STEP 7 V18 Assigning addresses and names to PROFINET devices PROFINET University Profinet Naming Convention If it matters, my application is using T_CONFIG with CONF_DATA and NOS to dynamically set a PROFINET device name. Those conditions being: My org has standardized on using EPLAN schematic names for device names, but EPLAN names include non-standard characters like "+" and/or start with a number instead of a letter. We have multiple machines where we'd like to use exactly the same PLC program besides different IPs and PROFINET names, which we can accomplish programmatically using T_CONFIG and a PLC index. Operator sets tag value of machine index in PLC or on HMI, then applies the change to trigger IP+PROFINET name updates. Docs make it clear how to do that part, but T_CONFIG requires the PROFINET name to already be converted. So I need to understand the rules for conversion so I can write that up in LAD/SCL/whatever.

Suggestion To thank Quote Answer

Regular Member

Joined: 1/11/2018

Last visit: 6/30/2025

Posts: 13

Rating:

(1)

How do I manually convert non-compliant PROFINET device names? Per multiple help docs it is clear to me the requirements for PROFINET device names which do not need to be converted. For example, st36000mio01 does not need to be converted, it is already compliant.

But when a name does need to be converted, it is not clear to me how that is done.

For example st36000_mio01 does need to be converted, and TIA Portal automatically converts it to st36000xbmio01f894. It appears underscores are always converted to xb and plus signs are always converted to xn. But where does the final f894 come from? There is a different suffix after every converted name and I do not know what that should be.

Relevant info which convers compliant names -- but do not cover the conversion for non-compliant names.

If it matters, my application is using T_CONFIG with CONF_DATA and NOS to dynamically set a PROFINET device name. Those conditions being:

My org has standardized on using EPLAN schematic names for device names, but EPLAN names include non-standard characters like "+" and/or start with a number instead of a letter.
We have multiple machines where we'd like to use exactly the same PLC program besides different IPs and PROFINET names, which we can accomplish programmatically using T_CONFIG and a PLC index. Operator sets tag value of machine index in PLC or on HMI, then applies the change to trigger IP+PROFINET name updates.

Docs make it clear how to do that part, but T_CONFIG requires the PROFINET name to already be converted. So I need to understand the rules for conversion so I can write that up in LAD/SCL/whatever.

9/6/2023 8:40 PM	Rate (0)
Micah Lindstrom Regular Member Joined: 1/11/2018 Last visit: 6/30/2025 Posts: 13 Rating: (1)	This is not a complete answer, but is is sufficient for my application. The final key was discovering the last four characters are a CRC16 checksum. To convert st36000_mio01 into st36000xbmio01f894 or ==plant=shop++line+36000_plc01 into xvxvplantxvshopxnxnlinexn36000xbplc01872d, use this algorithm: Replace all equal signs "=" with "xv" Replace all plus signs "+" with "xn" Replace all underscore "_" with "xb" Replace all spaces " " with "xa" Calculate a CRC16 checksum of the previous and append it to the end of the string Test putting st36000xbmio01 and xvxvplantxvshopxnxnlinexn36000xbplc01 into the calculator at https://crccalc.com, and you will see the CRC-16/ARC checksums are f894 and 872d, respectively, which match the string suffixes that TIA Portal automatically generated. Use "LGF_CalcCrc16Advanced" instead of "LGF_CalcCrc16" because the simpler one does not do the reflectInput and reflectResult that are required for CRC16 / ARC. Edit -- note this can be calculated in Microsoft Excel with a formula (no VBA necessary) incorporating this CRC generation guidance and this multi-substitution guidance (check out the REDUCE variants in the comments for doing any-to-any substitution rather than just one-to-one substitution). For example after adding a "crcArc16" formula to Excel using the Name Manager, you can add a "profinetStringToConvertedName" formula as well like the following. There are many cases it will not handle; feel free to share if you create expanded functionality. Example Excel LAMBDA formula for Name Manager: profinetStringToConvertedName(string) =LAMBDA(string,LET( substituteMulti,LAMBDA(text,oldvalues,newvalues,REDUCE(text,oldvalues,LAMBDA(a,b,SUBSTITUTE(a, b, XLOOKUP( b, oldvalues, newvalues,"" ))))), textCheckOnlyPermittedChar,LAMBDA(text,charArray, IF(PRODUCT(--(0<IFERROR(XMATCH(MID(text,SEQUENCE(LEN(text)),1),charArray),0))),TRUE,FALSE)), profinetSubstitute,LAMBDA(text,LOWER(substituteMulti(text, {"=";"+";"_";" "}, {"xv";"xn";"xb";"xa"}))), profinetPermittedCharsAtStart,CHAR(VSTACK(SEQUENCE(26,,CODE("a")),SEQUENCE(26,,CODE("A")))), profinetPermittedChars,VSTACK(profinetPermittedCharsAtStart,CHAR(SEQUENCE(10,,CODE("0"))),"-","."), profinetNameValid,LAMBDA(ascii, AND(textCheckOnlyPermittedChar(ascii,profinetPermittedChars), textCheckOnlyPermittedChar(LEFT(ascii,1),profinetPermittedCharsAtStart))), profinetName,LAMBDA(ascii, LET(a, LOWER(ascii), b, profinetSubstitute(a), IF(profinetNameValid(a), a, CONCAT(b,LOWER(crc16Arc(b)))))), profinetName(string) )) Due to character limits, I was able to include the substituteMulti formula within there, but crc16Arc must be defined as a separate formula within the name manager: crc16Arc (string) =LAMBDA(string,LET(ascii2bin,LAMBDA(a,CONCAT(BASE(CODE(MID(a, SEQUENCE(LEN(a)), 1)),2,8))), delimitedRows, LAMBDA(rowInterval,paddingInterval,paddingChar,rowLambda,string, LET(stringCharArray, MID(string,SEQUENCE(LEN(string)),1), qtyOfPadding, MOD(LEN(string),paddingInterval), paddingCharArray, IF(SEQUENCE(paddingInterval - qtyOfPadding), paddingChar), paddedStringCharArray, IF(qtyOfPadding=0, stringCharArray, VSTACK(paddingCharArray, stringCharArray)), BYROW(WRAPROWS(paddedStringCharArray, rowInterval, ""), rowLambda))), addDelimiterEveryXChar, LAMBDA(delimiterInterval,delimiterChar,paddingChar,string, TEXTJOIN(delimiterChar, TRUE, delimitedRows(delimiterInterval,delimiterInterval,paddingChar,LAMBDA(row, CONCAT(row)),string))), reflectString, LAMBDA(a,CONCAT(MID(a,SEQUENCE(LEN(a),,LEN(a),-1),1))), reflectStringByGroup, LAMBDA(delimiterInterval,paddingChar,string, TEXTJOIN("", TRUE, delimitedRows(delimiterInterval,delimiterInterval,paddingChar,LAMBDA(row, reflectString(CONCAT(row))),string))), nbit2dec, LAMBDA(a,SUM(MID( a, SEQUENCE(LEN(a)),1)*2^SEQUENCE(LEN(a),1,LEN(a)-1,-1))), formatHex, LAMBDA(a, MAP(a, LAMBDA(cell, DEC2HEX(nbit2dec(cell),4)))), crc,LAMBDA(messageBin,polyBin,reflectInput,reflectResult, LET(reflectCrcInput, LAMBDA(a, MAP(a, LAMBDA(cell, reflectStringByGroup(8,"0",cell)))), lenPoly, LEN(polyBin), reflectCrcResult, LAMBDA(a, MAP(a, LAMBDA(cell, reflectStringByGroup(lenPoly-1,"0",cell)))), messagePrepped, (CONCAT(IF(reflectInput,reflectCrcInput(messageBin),messageBin), SEQUENCE(lenPoly-1,,0,0))), polynomialDivision, REDUCE(LEFT(messagePrepped,lenPoly),SEQUENCE(LEN(messagePrepped)-lenPoly+1,,0), LAMBDA(a,i,CONCAT(IF((nbit2dec(a)>=POWER(2,lenPoly-1)), BASE(BITXOR(nbit2dec(a), nbit2dec(polyBin)),2), RIGHT(a,lenPoly-1)), MID(messagePrepped,lenPoly+1+i,1)))), IF(reflectResult,reflectCrcResult(polynomialDivision),polynomialDivision))), myCrc16Arc,LAMBDA(ascii, formatHex(crc(ascii2bin(ascii),"11000000000000101",TRUE,TRUE))), myCrc16Arc(string) )) Attachment profinetNameCrc16Arc.png (533 Downloads)
Last edited by: Micah Lindstrom at: 06/25/2024 18:06:32 Add note on how to accomplish in Excel Last edited by: Micah Lindstrom at: 08/07/2024 18:30:54 Last edited by: Micah Lindstrom at: 08/07/2024 18:35:03 Add Excel example LAMBDA formula for Name Manager Last edited by: Micah Lindstrom at: 06/01/2025 13:55:39 Add detail Last edited by: Micah Lindstrom at: 06/02/2025 16:00:19
Suggestion To thank Quote Answer
This contribution was helpful to 2 thankful Users Jen_Moderator Egon843

9/6/2023 8:40 PM

Rate (0)

Micah Lindstrom

Regular Member

Joined: 1/11/2018

Last visit: 6/30/2025

Posts: 13

Rating:

(1)

This is not a complete answer, but is is sufficient for my application. The final key was discovering the last four characters are a CRC16 checksum.

To convert st36000_mio01 into st36000xbmio01f894 or ==plant=shop++line+36000_plc01 into xvxvplantxvshopxnxnlinexn36000xbplc01872d, use this algorithm:

Replace all equal signs "=" with "xv"
Replace all plus signs "+" with "xn"
Replace all underscore "_" with "xb"
Replace all spaces " " with "xa"
Calculate a CRC16 checksum of the previous and append it to the end of the string

Test putting st36000xbmio01 and xvxvplantxvshopxnxnlinexn36000xbplc01 into the calculator at https://crccalc.com, and you will see the CRC-16/ARC checksums are f894 and 872d, respectively, which match the string suffixes that TIA Portal automatically generated.

Use "LGF_CalcCrc16Advanced" instead of "LGF_CalcCrc16" because the simpler one does not do the reflectInput and reflectResult that are required for CRC16 / ARC.

Edit -- note this can be calculated in Microsoft Excel with a formula (no VBA necessary) incorporating this CRC generation guidance and this multi-substitution guidance (check out the REDUCE variants in the comments for doing any-to-any substitution rather than just one-to-one substitution). For example after adding a "crcArc16" formula to Excel using the Name Manager, you can add a "profinetStringToConvertedName" formula as well like the following. There are many cases it will not handle; feel free to share if you create expanded functionality.

Example Excel LAMBDA formula for Name Manager:

profinetStringToConvertedName(string)

=LAMBDA(string,LET(
substituteMulti,LAMBDA(text,oldvalues,newvalues,REDUCE(text,oldvalues,LAMBDA(a,b,SUBSTITUTE(a, b, XLOOKUP( b, oldvalues, newvalues,"" ))))),
textCheckOnlyPermittedChar,LAMBDA(text,charArray, IF(PRODUCT(--(0<IFERROR(XMATCH(MID(text,SEQUENCE(LEN(text)),1),charArray),0))),TRUE,FALSE)),
profinetSubstitute,LAMBDA(text,LOWER(substituteMulti(text, {"=";"+";"_";" "}, {"xv";"xn";"xb";"xa"}))),
profinetPermittedCharsAtStart,CHAR(VSTACK(SEQUENCE(26,,CODE("a")),SEQUENCE(26,,CODE("A")))),
profinetPermittedChars,VSTACK(profinetPermittedCharsAtStart,CHAR(SEQUENCE(10,,CODE("0"))),"-","."),
profinetNameValid,LAMBDA(ascii, AND(textCheckOnlyPermittedChar(ascii,profinetPermittedChars), textCheckOnlyPermittedChar(LEFT(ascii,1),profinetPermittedCharsAtStart))),
profinetName,LAMBDA(ascii, LET(a, LOWER(ascii), b, profinetSubstitute(a), IF(profinetNameValid(a), a, CONCAT(b,LOWER(crc16Arc(b)))))),
profinetName(string)
))

Due to character limits, I was able to include the substituteMulti formula within there, but crc16Arc must be defined as a separate formula within the name manager:

crc16Arc (string)

=LAMBDA(string,LET(ascii2bin,LAMBDA(a,CONCAT(BASE(CODE(MID(a, SEQUENCE(LEN(a)), 1)),2,8))),
delimitedRows, LAMBDA(rowInterval,paddingInterval,paddingChar,rowLambda,string,
LET(stringCharArray, MID(string,SEQUENCE(LEN(string)),1),
qtyOfPadding, MOD(LEN(string),paddingInterval),
paddingCharArray, IF(SEQUENCE(paddingInterval - qtyOfPadding), paddingChar),
paddedStringCharArray, IF(qtyOfPadding=0, stringCharArray, VSTACK(paddingCharArray, stringCharArray)),
BYROW(WRAPROWS(paddedStringCharArray, rowInterval, ""), rowLambda))),
addDelimiterEveryXChar, LAMBDA(delimiterInterval,delimiterChar,paddingChar,string,
TEXTJOIN(delimiterChar, TRUE, delimitedRows(delimiterInterval,delimiterInterval,paddingChar,LAMBDA(row, CONCAT(row)),string))),
reflectString, LAMBDA(a,CONCAT(MID(a,SEQUENCE(LEN(a),,LEN(a),-1),1))),
reflectStringByGroup, LAMBDA(delimiterInterval,paddingChar,string,
TEXTJOIN("", TRUE, delimitedRows(delimiterInterval,delimiterInterval,paddingChar,LAMBDA(row, reflectString(CONCAT(row))),string))),
nbit2dec, LAMBDA(a,SUM(MID( a, SEQUENCE(LEN(a)),1)*2^SEQUENCE(LEN(a),1,LEN(a)-1,-1))),
formatHex, LAMBDA(a, MAP(a, LAMBDA(cell, DEC2HEX(nbit2dec(cell),4)))),
crc,LAMBDA(messageBin,polyBin,reflectInput,reflectResult,
LET(reflectCrcInput, LAMBDA(a, MAP(a, LAMBDA(cell, reflectStringByGroup(8,"0",cell)))),
lenPoly, LEN(polyBin),
reflectCrcResult, LAMBDA(a, MAP(a, LAMBDA(cell, reflectStringByGroup(lenPoly-1,"0",cell)))),
messagePrepped, (CONCAT(IF(reflectInput,reflectCrcInput(messageBin),messageBin), SEQUENCE(lenPoly-1,,0,0))),
polynomialDivision, REDUCE(LEFT(messagePrepped,lenPoly),SEQUENCE(LEN(messagePrepped)-lenPoly+1,,0),
LAMBDA(a,i,CONCAT(IF((nbit2dec(a)>=POWER(2,lenPoly-1)),
BASE(BITXOR(nbit2dec(a), nbit2dec(polyBin)),2), RIGHT(a,lenPoly-1)),
MID(messagePrepped,lenPoly+1+i,1)))),
IF(reflectResult,reflectCrcResult(polynomialDivision),polynomialDivision))),
myCrc16Arc,LAMBDA(ascii, formatHex(crc(ascii2bin(ascii),"11000000000000101",TRUE,TRUE))),
myCrc16Arc(string)
))

Attachment

profinetNameCrc16Arc.png (533 Downloads)

Last edited by: Micah Lindstrom at: 06/25/2024 18:06:32

Add note on how to accomplish in Excel

Last edited by: Micah Lindstrom at: 08/07/2024 18:30:54

Last edited by: Micah Lindstrom at: 08/07/2024 18:35:03

Add Excel example LAMBDA formula for Name Manager

Last edited by: Micah Lindstrom at: 06/01/2025 13:55:39

Add detail

Last edited by: Micah Lindstrom at: 06/02/2025 16:00:19

This contribution was helpful to

2 thankful Users

12/20/2024 3:22 PM	Rate (0)
Micah Lindstrom Regular Member Joined: 1/11/2018 Last visit: 6/30/2025 Posts: 13 Rating: (1)	Interestingly, latest PLC/firmware updates now have SHA checksum instructions. Too bad they didn't add CRC as well. https://support.industry.siemens.com/cs/tz/en/view/109478459 New functions with firmware V3.1 for S7-1500 and ET 200 CPUs (not R/H CPUs): New "SHA2" instruction – Cryptographic hash function: The asynchronous "SHA2" instruction enables an integrity check of data in order, for example, to check whether data were corrupted or a data range in a data block was changed during data transmission. A hash value is calculated for this. Versions SHA-224, SHA-256, SHA-384 and SHA-512 are supported.
Last edited by: Micah Lindstrom at: 12/20/2024 15:22:48 Last edited by: Micah Lindstrom at: 12/20/2024 15:23:08
Suggestion To thank Quote Answer

12/20/2024 3:22 PM

Rate (0)

Micah Lindstrom

Regular Member

Joined: 1/11/2018

Last visit: 6/30/2025

Posts: 13

Rating:

(1)

Interestingly, latest PLC/firmware updates now have SHA checksum instructions. Too bad they didn't add CRC as well.

https://support.industry.siemens.com/cs/tz/en/view/109478459

New functions with firmware V3.1 for S7-1500 and ET 200 CPUs (not R/H CPUs):
New "SHA2" instruction – Cryptographic hash function:
The asynchronous "SHA2" instruction enables an integrity check of data in order, for example, to check whether data were corrupted or a data range in a data block was changed during data transmission. A hash value is calculated for this.
Versions SHA-224, SHA-256, SHA-384 and SHA-512 are supported.

SiePortal

Created by: Micah Lindstrom at: 7/3/2023 4:37 PM (2 Replies)

Rating (0)

Thanks 2

3 Entries

Micah Lindstrom

Micah Lindstrom

Attachment

Last edited by: Micah Lindstrom at: 06/25/2024 18:06:32

Last edited by: Micah Lindstrom at: 08/07/2024 18:30:54

Last edited by: Micah Lindstrom at: 08/07/2024 18:35:03

Last edited by: Micah Lindstrom at: 06/01/2025 13:55:39

Last edited by: Micah Lindstrom at: 06/02/2025 16:00:19

This contribution was helpful to

Micah Lindstrom

Last edited by: Micah Lindstrom at: 12/20/2024 15:22:48

Last edited by: Micah Lindstrom at: 12/20/2024 15:23:08

3 Entries

Related topics by keywords:

Follow us on

SiePortal

Procedure to convert PROFINET device names

Created by: Micah Lindstrom at: 7/3/2023 4:37 PM (2 Replies)

Rating (0) Thanks 2

3 Entries

Micah Lindstrom

Micah Lindstrom

Attachment

Last edited by: Micah Lindstrom at: 06/25/2024 18:06:32

Last edited by: Micah Lindstrom at: 08/07/2024 18:30:54

Last edited by: Micah Lindstrom at: 08/07/2024 18:35:03

Last edited by: Micah Lindstrom at: 06/01/2025 13:55:39

Last edited by: Micah Lindstrom at: 06/02/2025 16:00:19

This contribution was helpful to

Micah Lindstrom

Last edited by: Micah Lindstrom at: 12/20/2024 15:22:48

Last edited by: Micah Lindstrom at: 12/20/2024 15:23:08

3 Entries

Related topics by keywords:

Follow us on

Rating (0)

Thanks 2