FUNCTION "StringSplit" : Bool

{ S7_Optimized_Access := 'TRUE' }

VERSION : 0.1

VAR_INPUT

  Delimiter : String;

END_VAR

VAR_OUTPUT

  NumSplits : DInt;   // Number of splits

END_VAR

VAR_IN_OUT

  StringToSplit : String;

  OutputArray : Array[*] of String;

END_VAR

VAR_TEMP

  tUpper : DInt;

  tStrLen : DInt;

  tStr : String;

  tIdx : DInt;

  tDelimiterPos : DInt;

  tDelimiterLen : DInt;

  tElementLen : DInt;

  tRestLen : DInt;

END_VAR

BEGIN

  //get the bounds of the array

  #tUpper := UPPER_BOUND(ARR := #OutputArray, DIM := 1);

  //initialize loop

  #tStrLen := LEN(#StringToSplit);

  #tStr := #StringToSplit;

  #tIdx := LOWER_BOUND(ARR := #OutputArray, DIM := 1);

  #NumSplits := 0;

  #tDelimiterLen := LEN(#Delimiter);

  //split string loop

  WHILE #tStrLen > 0 AND #tIdx <= #tUpper DO

    #tDelimiterPos := FIND(IN1 := #tStr, IN2 := #Delimiter);

    IF #tDelimiterPos > 0 THEN

      #tElementLen := #tDelimiterPos - 1;

      #OutputArray[#tIdx] := LEFT(IN := #tStr, L := #tElementLen);

      #tRestLen := #tStrLen - #tDelimiterPos - #tDelimiterLen + 1;

      #tStr := RIGHT(IN := #tStr, L := #tRestLen);

    ELSE

      #OutputArray[#tIdx] := #tStr;

      #tStr := '';

    END_IF;

    #tStrLen := LEN(#tStr);

    #NumSplits += 1;

    #tIdx += 1;

  END_WHILE;

  //clear the remaining elements

  WHILE #tIdx <= #tUpper DO

    #OutputArray[#tIdx] := '';

    #tIdx := #tIdx + 1;

  END_WHILE;

  //success if the array is large enough to hold all the strings

  //(although it is possible for the elements to be concatenated)

  #StringSplit := #tStrLen = 0;

END_FUNCTION

{ S7_Optimized_Access := 'TRUE' }

VERSION : 0.1

VAR_INPUT

str2Parse : WString;

str2Find : WString;

END_VAR

VAR_OUTPUT

outSplitStringArray : Array[1..10] of WString;

END_VAR

VAR_TEMP

strLen : Int;

strTemp : WString;

elementNum : Int;

delimiterPos : Int;

elementLen : Int;

restLen : Int;

END_VAR

BEGIN

// This block is used to analyse a supplied input string and chop it up into shorter bits based on the

// supplied input string that is to be found

// Reset the output array

FOR #elementNum := 1 TO 10 DO

#outSplitStringArray[#elementNum] := WString#'';

END_FOR;

// Initialise variables

#strLen := LEN(#str2Parse);

#strTemp := #str2Parse;

#elementNum := 0;

//Loop through the string to process it

WHILE #strLen > 0 AND #elementNum < 10 DO

#elementNum := #elementNum + 1;

#delimiterPos := FIND(IN1 := #strTemp, IN2 := #str2Find);

IF #delimiterPos > 0 THEN

#elementLen := #delimiterPos - 1;

#outSplitStringArray[#elementNum] := LEFT(IN := #strTemp, L := #elementLen);

#restLen := #strLen - #delimiterPos - (LEN(#str2Find) - 1);

#strTemp := RIGHT(IN := #strTemp, L := #restLen);

ELSE

#outSplitStringArray[#elementNum] := #strTemp;

#strTemp := WString#'';

END_IF;

#strLen := LEN(#strTemp);

END_WHILE;

END_FUNCTION