Hi,

I took the liberty to revise the code a bit and add the latest request "starting motors according to less running hours".

The FB now contains an input which allows you to; Select motor according to priority number "1 to 4, least to most running hours". The output which corresponds to that priority number will be activated.

This is the code:

FUNCTION_BLOCK "FB_Sort_Revised1"
{ S7_Optimized_Access := 'FALSE' }
VERSION : 0.1
   VAR_INPUT
      "diMotor1Hours" : DInt := 15;   // Running hours of motor 1
      "diMotor2Hours" : DInt := 1;   // Running hours of motor 2
      "diMotor3Hours" : DInt := 25;   // Running hours of motor 3
      "diMotor4Hours" : DInt := 3;   // Running hours of motor 4
      "PriorityNoMotorToActivate" : Int;   // Select motor according to priority number "1 to 4, least to most running hours"
   END_VAR

   VAR_OUTPUT
      "MotorNumberSorted" : array[1..4] of Int;   // Array which contains the sorted motor numbers, smallest index contains motor with least running hours
      "doMotor1" : Bool;   // Output for motor 1, output will be activated depending on which Priority number is given at the input
      "doMotor2" : Bool;   // Output for motor 2, output will be activated depending on which Priority number is given at the input
      "doMotor3" : Bool;   // Output for motor 3, output will be activated depending on which Priority number is given at the input
      "doMotor4" : Bool;   // Output for motor 4, output will be activated depending on which Priority number is given at the input
   END_VAR

   VAR_TEMP
      "i" : Int;
      "j" : Int;
      "adiNo" : ARRAY[1..4] OF Int;
      "adiMotor" : ARRAY[1..4] OF DInt;
      "adPumpOutput" : ARRAY[1..4] OF Bool;
      "temp_motor" : DInt;
      "temp_no" : Int;
   END_VAR

BEGIN
 // assign input values to array
 #adiMotor[1] := #diMotor1Hours;
 #adiMotor[2] := #diMotor2Hours;
 #adiMotor[3] := #diMotor3Hours;
 #adiMotor[4] := #diMotor4Hours;
 
 
 // numerate
 FOR #i := 1 TO 4 DO
   #adiNo[#i] := #i;
   #adPumpOutput[#i] := false;
   END_FOR;
 
 // sort low to high
 FOR #i := 1 TO 4 DO
   FOR #j := #i+1 TO 4 DO
     IF #adiMotor[#i] > #adiMotor[#j] THEN
       #temp_motor :=  #adiMotor[#i];
       #adiMotor[#i] := #adiMotor[#j];
       #adiMotor[#j] := #temp_motor;
      
       #temp_no := #adiNo[#i];
       #adiNo[#i] := #adiNo[#j];
       #adiNo[#j] := #temp_no;
     END_IF;
   END_FOR;
   END_FOR;
  
   // move to output
   #MotorNumberSorted := #adiNo;
 
 // activate pump output according to selected pump by priority number
 #adPumpOutput[#MotorNumberSorted[#PriorityNoMotorToActivate]] := true;
 
 
 // array to outputs
 #doMotor1 := #adPumpOutput[1];
 #doMotor2 := #adPumpOutput[2];
 #doMotor3 := #adPumpOutput[3];
 #doMotor4 := #adPumpOutput[4];
END_FUNCTION_BLOCK

I hope someone can use this. Feel free to ask questions or adjust the code to your needs.

Kind regards,
Jens