Checking DB bits

TheDuke.

Thanks for the answer.

I just wanted to know if this function was available. I always used a series of comperators to check this so in the end, this is usefull. Now I know I don't need to search for this function anymore :)

feel free to use attached AWL - source to check a number of words
if any bit is "1".

Parameter:

T_DB : DB to check

A_Wort : Number of first word you like to check

Anzahl : Amount of words you like to check

TEST : Output at least one bit in checked words is "1"

Dear TheDuke,


Building on the comments given by Huggy andIBN I will add another approach that mightbe helpful. Let's say you decide to use an array of boolsto hold all your alarmbits, then you could check if a bit in that array is one. This will work regardingthe size of that array, so this means, you won't have to change the length each time you add an extra boolean to your array, nor will you have to deal with absolute addresses. You just use an any pointer to point to your array and let that pointer get the information you need.
If this is something that you could use then youthis is what you could do:
- Use an array of bools that hold all of you alarm bits (AlarmArray[0..25] of bool);
- Create an anypointer that point to that array;
- Use blkmov to move the data from your array Byte by Byte for further checking;
- Check if the byte is greater than 0;
- If it is set alarmoutput to "1", if it isn't set the output to "0".

The code will look something like this:
[code]
FUNCTION_BLOCK "FB_ScanForOne"
{ S7_Optimized_Access := 'FALSE' }
VERSION : 0.1
VAR_INPUT
"DBanyPtr" : Any; // any pointer that points to your array, struct or udt
"ATDBanyPtr" AT "DBanyPtr" : Struct // dissasembled any pointer
"s7code" : Byte;
"DataType" : Byte;
"Length" : Int;
"DBnumber" : Int;
"MemArea" : Byte;
"MSAddress" : Byte;
"LSAddress" : Word;
END_STRUCT;
END_VAR

VAR_OUTPUT
"do_alarm" : Bool; // alarm output
END_VAR

VAR
"Length" : Int;
"DBNumber" : Int;
"RetVal" : Int;
"CheckValue" : Byte;
END_VAR

VAR_TEMP
"i" : Int;
END_VAR

BEGIN
#RetVal := 0;

// SET
#ATDBanyPtr.s7code := 16#10; // Set code for s7
#ATDBanyPtr.DataType := 16#02; // Set data type to byte
#ATDBanyPtr.LSAddress := 0; // Define start address
#ATDBanyPtr.MemArea := B#16#84; // Set Memory area to data block


// GET
#Length := #ATDBanyPtr.Length; // Get length
#DBNumber := #ATDBanyPtr.DBnumber; // Get DB number

#ATDBanyPtr.Length := 1; // Byte per byte check

FOR #i := 0 TO #Length-1 DO // do for scanned length
#RetVal := BLKMOV(SRCBLK:=#DBanyPtr, DSTBLK=>#CheckValue); // Move from mem area to another, Byte from DB to #CheckValue
IF #RetVal <> 0 THEN // when error on move then exit the block
RETURN;
END_IF;
IF #CheckValue = 16#00 THEN // check if value is 0, no "1" state detected
#do_alarm := false; // no alarm if only "0" is detected
#ATDBanyPtr.LSAddress := INT_TO_WORD(WORD_TO_INT(#ATDBanyPtr.LSAddress) + 8); // increase pointer (pointer is bitwise, so "+8" means we increase the byte address)
ELSE
#do_alarm := true; // if other than "0" is detected (this means one is detected) then set alarm output
RETURN; // exit the block
END_IF;
END_FOR;
END_FUNCTION_BLOCK
[/code]

This script will work on structures, arrays and UDT's, so you have the freedom to use whatever you want, as long as all alarmbits are grouped under the samedatatype you will be fine. You could even checkif an integer is other than zero in anarray of integers, ...

Hope this helps.


Kind regards,
Jens

huggy_d1

Jens,
Does this method also work on the s7-1200 family with all firmware revisions? I know we have some troubles with the ANY pointer type on those devices.

Hi Duke,


I revised my previous program, since I thought it was too much code for too little action. I simplified and improved it a bit. Now you can check all variables in adatablock for a "1" state. They don't have to be grouped in a structure or whatever, you just point to the firstvariable in your datablock (bit byte or whatever)and you're done.

This is the SCL code:
[code]
FUNCTION_BLOCK "FB_ScanForOne_V2"
{ S7_Optimized_Access := 'FALSE' }
VERSION : 0.1
VAR_INPUT
"DBPtr" : Pointer;
"ATDBPtr" AT "DBPtr" : Struct
"DBNumber" : Word;
"MemArea" : Byte;
"MSAddress" : Byte;
"LSAddress" : Word;
END_STRUCT;
END_VAR

VAR_OUTPUT
"do_alarm" : Bool;
END_VAR

VAR
"dbInfo" : Struct
"DB_Retval" : Int;
"DB_Length" : Word;
"DB_WriteProt" : Bool;
END_STRUCT;
"ByteToCheck" : Byte;
END_VAR

VAR_TEMP
"i" : Int;
END_VAR

BEGIN
// Get DB information
#dbInfo.DB_Retval := TEST_DB(DB_NUMBER:=#ATDBPtr.DBNumber, DB_LENGTH=>#dbInfo.DB_Length, WRITE_PROT=>#dbInfo.DB_WriteProt); // GET DB Length in BYTES

FOR #i := 0 TO WORD_TO_INT(#dbInfo.DB_Length) - 1 DO // LOOP for all BYTES in the DB
#ByteToCheck := WORD_TO_BLOCK_DB(#ATDBPtr.DBNumber).DB(#i); // CHECK the DB Byte Per Byte
IF BYTE_TO_INT(#ByteToCheck) > 0 THEN // IF the BYTE is greater than "0" THEN set the alarm output (we can call this: CHECK FOR "1")
#do_alarm := true;
RETURN; // EXIT BLOCK when an alarm is found (no need to check further)
ELSE
#do_alarm := false; // NO alarms means NO alarm output
END_IF;
END_FOR;
END_FUNCTION_BLOCK

[/code]

Let's say the first variable in your datablock "DB_ScanForOne"is named "Alarm" and the alarm output is "Q0.0" then function block "FB_ScanForOne_V2" would look something like this in OB1:
[code]
CALL "FB_ScanForOne_V2", "FB_ScanForOne_V2_DB"
( DBPtr := "DB_ScanForOne_TestDB".Alarm ,
do_alarm :=%Q0.0 );
NOP 0;
[/code]

Now you can check if a variable is "1"independently ofthe size and datatypes in your datablock.

Note that this code can contain bugs, you can always fine-tune it.

Hope this is of any use, if it's not atleast I had some fun.


Kind regards,
Jens