Determine DB size dynamically (S7-1200) - solved

What are you looking for exactly?

The logic is not a project.  It is a single block.

FUNCTION_BLOCK "Get_DB_Size"

TITLE =  Get a DB's Size

{ S7_Optimized_Access := 'TRUE' }

AUTHOR : 0_Einstein

VERSION : 0.3

//Return DB size using ENO to generate fault when PEEK beyond DB bounds (per Siemens Support)

//FB attribute "Set ENO automatically" must be enabled

//NOTE : verified to work for s7-1200 in V13 SP1

VAR_INPUT DB_SPECIFIC

  db_Num : UInt;

END_VAR

VAR_OUTPUT

  Size : UInt;   // default db size=0

END_VAR

VAR

  db_index : UInt;

  db_byte : Byte;

  trapped_error {InstructionName := 'ErrorStruct'; LibVersion := '1.0'} : ErrorStruct;

END_VAR

VAR_TEMP

  max_index : UInt;

  err_id : Word;

END_VAR

BEGIN

  //-------------------------------------------------------------------

  #db_index := 0;      // initialize

  #max_index := 1000;  // set a constraint to prevent watchdog timeouts

  //===================================================================

  // not strictly required to handle errors internally

  // but if a FW or service pack or update suddenly causes errors,

  // this should prevent cpu crashes

  // ==================================================================

  //

  // clear out any existing error conditions

  #err_id := GET_ERR_ID();

  // emulates TRY ... CATCH ... found in other computer languages

  REPEAT

    ENO := true;  // required to make it work

    // try to look at byte @ db_index

    #db_byte := PEEK(area:=16#84, dbNumber:=#db_Num, byteOffset:=#db_index);

    #db_index += 1;

  UNTIL (#db_index >= #max_index) OR (NOT ENO) END_REPEAT;

  IF NOT ENO THEN

    #Size := #db_index-1;  // copy count when ENO went off (before inc(1) )

  ELSE

    #Size := 0;            // DB does not exist or is very large

  END_IF;

  RETURN;

END_FUNCTION_BLOCK

vorapob

Rakeysh

Could you please share that backup of PLC

Dear Experts,

 I agree with you.

Could you please share your completed code in project to us.

Best Regards,