Skip to Content

Register Login

Industry Online Support

Technical Forum

Navigation

TIA SCL, Length of "PLC data types"

Created by: TIM77 at: 6/19/2012 2:45 PM (10 Replies)

Rating (3)

Thanks 8

Result pages:: |; 1 | 2; |

11 Entries

Entries per page: 10 | all

6/19/2012 2:45 PM	Rate (0)
TIM77 Advanced Member Joined: 5/7/2012 Last visit: 12/4/2023 Posts: 35 Rating: (2)	I have an array of custom "PLC data type". The PLC data type will consist of multiple data elements, but the first element will always be an ID of type INT. I would like to like to make a generic FB that takes the array and an ID as input and returns the index to the entry in the array that corresponds to the ID. I have found how I can pass an array of unknown length using the ANY pointer: /tf/WW/en/Posts/71210 However, I would have to know the length of the "PLC data type" to be able to find the ID. Is this possible?

Suggestion To thank Quote Answer

6/19/2012 3:08 PM	Rate (0)
0_Einstein Diamond Expert Joined: 7/7/2010 Last visit: 12/7/2023 Posts: 13989 Rating: (2282)	TIM77 I have an array of custom "PLC data type". The PLC data type will consist of multiple data elements, but the first element will always be an ID of type INT. I would like to like to make a generic FB that takes the array and an ID as input and returns the index to the entry in the array that corresponds to the ID. I have found how I can pass an array of unknown length using the ANY pointer: /tf/WW/en/Posts/71210 However, I would have to know the length of the "PLC data type" to be able to find the ID. Is this possible? Is this for 300/400 or S7-1200 PLCs you intend to target this generic data type? Since you have to define the datatype in advance, be sure and create your array using the standard rather than optimal structure so you can see the offset values. Then your data sizes are calculated for you. SInt/Byte/Char : 1 byte UInt/Int/Word : 2 bytes DInt/DWord/Real : 4 bytes LReal : 8 bytes (I think) string : 256 bytes string[x] : x+2 bytes With the AT overlay construct, you can access individual bytes of your array, but not if you pass just a pointer to the array. Are you looking to create a generic array and put values in it based on some arbitrary data type determined kind of on the fly? Or, are you predefining the array with precision and want to randomly access various array elements without looping through it every time?
	science guy
Suggestion To thank Quote Answer
This contribution was helpful to 1 thankful Users Abdza

6/19/2012 4:01 PM	Rate (0)
TIM77 Advanced Member Joined: 5/7/2012 Last visit: 12/4/2023 Posts: 35 Rating: (2)	Hi huggy and thanks for your reply. This is for a S7-300 PLC The table will be used as lookup table. My plan was to loop through the table to find the ID. If the ID doesn't exist, the one closest would be returned. The IDs will be stored in ascending order. The table (Array of data types) will be read from a text file and downloaded to a DB from the HMI unit and the number of elements is unknown and must be found during runtime. Also I would like to use the same FB on multiple tables. As you say, the datatype will be created in advanced so a solution is to have a SIZE input where I "manually" enter the size. But if it is possible to avoid it, the interface would be cleaner. Can I use the AT command also if I want to be able to use the FB on different Arrays with different data types. (Only the ID field, which is the first column, is common for the different tables)

Suggestion To thank Quote Answer

6/19/2012 4:50 PM	Rate (1)
0_Einstein Diamond Expert Joined: 7/7/2010 Last visit: 12/7/2023 Posts: 13989 Rating: (2282)	TIM77 Hi huggy and thanks for your reply. This is for a S7-300 PLC The table will be used as lookup table. My plan was to loop through the table to find the ID. If the ID doesn't exist, the one closest would be returned. The IDs will be stored in ascending order. The table (Array of data types) will be read from a text file and downloaded to a DB from the HMI unit and the number of elements is unknown and must be found during runtime. Also I would like to use the same FB on multiple tables. As you say, the datatype will be created in advanced so a solution is to have a SIZE input where I "manually" enter the size. But if it is possible to avoid it, the interface would be cleaner. Can I use the AT command also if I want to be able to use the FB on different Arrays with different data types. (Only the ID field, which is the first column, is common for the different tables) With the 300 level PLCs, you have more direct access to DBs than with the 1200 level PLCs. You can do much more than I am able to test and suggest. Hopefully someone using the portal on the 300/400 PLCs can suggest some good SCL routine(s) that do exactly what you are doing. The OSCAT library may have some good sample code that solves your problem. Google it if you have not seen it before. Lot of open source code. Someone posted the code exported to SCL making it easy for me to use some of the routines in the 1200 PLCs I routinely use.
	science guy
Suggestion To thank Quote Answer
This contribution was helpful to 1 thankful Users TIM77

6/21/2012 4:33 PM	Rate (0)
smiffy Platinum Expert Joined: 1/17/2007 Last visit: 12/6/2023 Posts: 1527 Rating: (528)	Not sure exactly what you are wanting to do. But it seems that you want to find the type and size of an array within a DB, and also access an interger called ID from within the same DB at position 0. If I have understood this correctly, the following code should work. I have given it a quick test and it seems to work. Given that you have a shared DB called "DATADB" that have an element called "ID" at postion 0, followed by an array of any type and size called "DATA". You will also need an instance DB for my FB, which we will assume is DB14. My FB will need to be called using the form:- FB995.DB14(P_DATA := DATADB.DATA); My FB:- [code] FUNCTION_BLOCK FB995 TITLE = 'ANY Pointer Test' AUTHOR : Smiffy VAR_INPUT P_ARRAY : ANY; // Pointer to the array within the DB (needs to be set to DBn.ArrayName from calling FC/FB) END_VAR VAR_TEMP pArr : ANY; // Input variable ANY pointer - used for accessing variable data and type pAnyArr AT pArr : STRUCT // Diassembled ANY pointer structure S7Code : BYTE; // Code for S7 DataType : BYTE; // Code for data type Length : INT; // Repetition factor = Send/receive length DBNumber : INT; // Data block Number MemoryArea : BYTE; // Specified memory area ByteAddressMSB : BYTE; // Byte address most significant bits ByteAddressLSB : WORD; // Byte address least significant bits END_STRUCT; END_VAR VAR RetVal : INT; ID : INT; ArrayLength : INT; ArrayType : INT; END_VAR // Get details of the array from within the DB pArr := P_ARRAY; // Pointer to the array structure within the DB ArrayType := BYTE_TO_INT(pAnyArr.DataType); // Get array data type ArrayLength := pAnyArr.Length; // Get array length in data type units (e.g. INTs, REALs, WORDs etc.) // Now read the ID value from the DB assuming that it is the first item in the DB pAnyArr.DataType := 16#05; // Set ANY pointer data type to INT (ID is INT type) pAnyArr.Length := 1; // Set length up to copy 1 INT pAnyArr.ByteAddressLSB := 0; // Set address so that it points to the first item in the DB RetVal := BLKMOV(SRCBLK := pArr, DSTBLK := ID); // Copy over the ID value from the ID value from the DB to loacl variable IF RetVal = 0 THEN // If BLKMOV was sucessful then... ; // Insert your test code here END_IF; END_FUNCTION_BLOCK [/code] ArrayType contains the datatype of the array (01=BOOL, 02=BYTE, 03=CHAR, 04=WORD, 05=INT, 06=DWORD, 07=DINT, 08=REAL, 09=DATE, 0A=TOD, 0B=TIME, 0C=S5TIME, 0E=DT, 13=STRING). ArraySize contains the amount of array elements (NOT the amount of bytes). Hope this is of help.
	Programming today is the race between software engineers building bigger and better idiot proof programs, and the universe producing bigger and better idiots. So far, the universe is winning...
Suggestion To thank Quote Answer
This contribution was helpful to 1 thankful Users TIM77

6/22/2012 10:21 AM	Rate (0)
TIM77 Advanced Member Joined: 5/7/2012 Last visit: 12/4/2023 Posts: 35 Rating: (2)	Thanks for the example smiffy. Your code is quite similar to what I currently have achieved. Which is not strange as I have based it on an example you have written previously that I found in the forum. But just to clarify my problem. I have a lookup tables in a text file. One of the tables looks like this: \| ID \| Motor1 SP (Real) \| Fan on (Bool) \| \| 1 \| 12,5 \| false \| \| 3 \| 12,5 \| true \| ……. This is just one example as there are many of them and as you can see the table consists of variable of different types. The text file will be read in the HMI unit and downloaded to the PLC. My Idea of how to implement this was to use a function in the TIA portal called "PLC data types". I don't know if this is something new to the TIA portal as I am new to this, but to me this looks similar to a STRUCT. So I have made a data type with the following elements [ID(int), Motor1 SP(Real), Fan_on (Bool)]. Then I made an array of this data type and filled it with the data from the text file. Now I need a way to search through the array with elements of this data type. For example I want to search through the array and find the index to the element with ID=3. Using the method you described, I can do this. However, I need to know the size of the data type to know what "ByteAddressLSB" should be incremented with. Currently, I have an input to my FB where I manually calculate this value and it works fine. But I would prefer, if it possible, to find this size by code.

Suggestion To thank Quote Answer

6/26/2012 3:44 PM	Rate (1)
smiffy Platinum Expert Joined: 1/17/2007 Last visit: 12/6/2023 Posts: 1527 Rating: (528)	Ok I have had a second go at it. It is not possible to work out the UDT size directly from the DB, but you can from a local copy of the UDT. This is OK as you will need to have a local UDT var anyhow as you need to copy the DB data over to it for testing the ID. The block is called with the DB_PTR input set to point at the array of structures in the DB (DBn.ArrayName) and the SRC_ID set to the ID you want to find. This is shown in the image PtrTestFBRuntime.jpg. The DB structure is shown in the image PtrTestDBDeclaration.jpg. The DB test data is shown in the image PtrTestDBRuntime.jpg. Here is the new code. [code] TYPE UDT995 // Your structure STRUCT ID : INT; MOTOR_SP : REAL; FAN_ON : BOOL; END_STRUCT END_TYPE FUNCTION_BLOCK FB995 TITLE = 'ANY Pointer Test' AUTHOR : Smiffy VAR_INPUT SRC_ID : INT; // ID to search for DB_PTR : ANY; // Pointer to array within DB (DBn.ArrayName) END_VAR VAR_OUTPUT DATA : UDT995; // Local UDT definition for calculating the UDT size (could be in TEMP or VAR section if required) END_VAR VAR_TEMP pArr : ANY; // Input variable ANY pointer - used for accessing variable data and type pAnyArr AT pArr : STRUCT // Diassembled ANY pointer structure S7Code : BYTE; // Code for S7 DataType : BYTE; // Code for data type Length : INT; // Repetition factor = Send/receive length DBNumber : INT; // Data block Number MemoryArea : BYTE; // Specified memory area ByteAddressMSB : BYTE; // Byte address most significant bits ByteAddressLSB : WORD; // Byte address least significant bits END_STRUCT; END_VAR VAR RetVal : INT; ArraySize : INT; // Size of UDT in bytes NumElements : INT; // Number of array elements in the DB ID : INT; // Local ID for testing purposes I : INT; // Loop counter END_VAR pArr := DATA; // Pointer to the local UDT type ArraySize := pAnyArr.Length; // Get the size of our UDT type in bytes pArr := DB_PTR; // Pointer to the array structure within the DB NumElements := pAnyArr.Length / ArraySize; // Number of array elements = size of full UDT type array / size of 1 UDT type FOR I := 1 TO NumElements DO // Loop for all array elements in DB Retval := BLKMOV(SRCBLK := pArr, DSTBLK := DATA); // Copy UDT element to local UDT for testing IF RetVal = 0 THEN // If copy sucessful IF SRC_ID = DATA.ID THEN // If DB ID matches search ID we have found our man! ; // Add you code here for whatever you want to do when you have found a match EXIT; // Optional loop exit on ID value found (might want to match several at once, if so remove this) END_IF; ELSE ; // Copy unsucessful - might want to consider some form of error handling here END_IF; // Bump pointer by array size * 8 to convert to bytes to address, so that it points to the next array element in DB pAnyArr.ByteAddressLSB := INT_TO_WORD(WORD_TO_INT(pAnyArr.ByteAddressLSB) + (ArraySize * 8)); END_FOR; // Next array element END_FUNCTION_BLOCK [/code] Attachment PtrTest.zip (395 Downloads)
	Programming today is the race between software engineers building bigger and better idiot proof programs, and the universe producing bigger and better idiots. So far, the universe is winning...
Suggestion To thank Quote Answer
This contribution was helpful to 2 thankful Users TIM77 AZRAIQI

6/27/2012 9:29 AM	Rate (0)
TIM77 Advanced Member Joined: 5/7/2012 Last visit: 12/4/2023 Posts: 35 Rating: (2)	Thanks smiffy. This seems to be exactly what I'm looking for.

Suggestion To thank Quote Answer
This contribution was helpful to 2 thankful Users smiffy AZRAIQI

6/27/2012 2:18 PM	Rate (0)
TIM77 Advanced Member Joined: 5/7/2012 Last visit: 12/4/2023 Posts: 35 Rating: (2)	Dear smiffy, A couple of questions: When incrementing the pointer to the next element: pAnyArr.ByteAddressLSB := INT_TO_WORD(WORD_TO_INT(pAnyArr.ByteAddressLSB) + (ArraySize * 8)); Is it necessary to check for wraparound to see if also ByteAddressMSB also needs to be incremented? Also, I see that it works, but why don't we have to remove the first 3 bits in ByteAddressLSB that, according to the help text, contains bit address
	Last edited by: TIM77 at: 6/27/2012 3:17 PM
Suggestion To thank Quote Answer

6/27/2012 4:23 PM	Rate (1)
smiffy Platinum Expert Joined: 1/17/2007 Last visit: 12/6/2023 Posts: 1527 Rating: (528)	Well spotted. You are correct in what you say. But I am using a little dodge. I am keeping the MSB at zero to keep the coding simple. This will work fine unless you go over the address limit than can be held in the LSB. As the LSB is a WORD and the address is bit-wise encoded, the highest memory address in the DB than can be address would be 2^16/8 bytes = 8192. So given that you UDT is 8 bytes in size, this limits you to an array size of 1024 structures. I have an solution for going over this limit, but it adds a bit more code, and makes the code a little harder to understand. So I left it out for size / clarity reasons. I can produce some code that will work past this limit if you require. Are you likely to need more than 1024 array elements? BLKMOV can only work with byte alligned addresses, so that is why the address have to be incremented by 8 every time. Plus we work out the array size in bytes so the addressed has to be moved on by a defined number of bytes (8 in this case = 64 bits).
	Programming today is the race between software engineers building bigger and better idiot proof programs, and the universe producing bigger and better idiots. So far, the universe is winning...
Suggestion To thank Quote Answer

|

Share this page:

Share this page on...

Follow us on