Auto assigned timers

Hi

use multiple instance capability i.e. create a variable in parent FB STAT area instead of crreating a DB for each FB call.

in stat let's say

T_TIMER_1 :  TON; // Timer 1instance

then you call function and assign T_TIMER_1 instead of instance DB

Example solution below - paste it to Source editor and compile.

note: assign name in Symbols otherwise compile fail

1. call function with ALL selectors FALSE in first Network of OB1

2. call function when timer required with ONE selector always ON (to select kind of timer)

3. variable assigned to IQ must be stat or M accessible in whole program

4. do not use in interrupts. only in blocks called from OB1

5. do not skip call in any circumstances

Code below (may need debugging)

 FUNCTION "S5_TIMER" : BOOL // define S5_TIMER : FC xxx in Symbols Editor
TITLE =Timer using S5Time Timers
//first call with all modes = false to reset timer nunber on each scan.
//do not use in interrupt OBs. use ONLY in FC/FBs called from OB1
//and timers not to be skipped by Jump instructions!!!
VERSION : 0.1


VAR_INPUT
I_TRIGGER : BOOL ;    //Timer Trigger
I_TIMER_RESET : BOOL ;    //Timer RESET
I_PULSE : BOOL ;    //Timer Mode: Pu;se
I_PEXT : BOOL ;    //Timer Mode: Pulse Extended
I_ODT : BOOL ;    //Timer Mode: On Delay
I_ODTS : BOOL ;    //Timer Mode: Retentive On Delay
I_OFFDT : BOOL ;    //Timer Moce: Off Delay
I_PT : S5TIME ;    //Timer Setpoint
END_VAR
VAR_IN_OUT
IQ_TIMER_NO : INT ;    //Timer Number
END_VAR
VAR_TEMP
Timer_No : INT ;
END_VAR
BEGIN
NETWORK
TITLE =Cyheck all modes 0 and reset timer number



AN    #I_PULSE;
AN    #I_PEXT;
AN    #I_ODT;
AN    #I_ODTS;
AN    #I_OFFDT;
JNB   _001;
L     0;
T     #IQ_TIMER_NO;
SET   ;
SAVE  ;
CLR   ;
_001: A     BR;
SAVE  ;
BEC   ;
NETWORK
TITLE =Copy Timer Number and update for next Call

L     #IQ_TIMER_NO; // tmer nunmber
T     #Timer_No; // store in local variable
+     1; // Increment by 1
T     #IQ_TIMER_NO; // return incremented for next call
NETWORK
TITLE =Check if Pulse Selected



AN    #I_PULSE;
JC    PEXT;
NETWORK
TITLE =Line Control: Air Wipes Off Delay when line jog fed/run disappea

A     #I_TRIGGER; // Trigger
L     #I_PT;
SP    T [#Timer_No];
A     #I_TIMER_RESET;
R     T [#Timer_No];
A     T [#Timer_No];
=     #RET_VAL;
SAVE  ;
BE    ;
NETWORK
TITLE =Check if Extended Pulse Selected

PEXT: AN    #I_PEXT;
JC    ODT;
NETWORK
TITLE =Line Control: Air Wipes Off Delay when line jog fed/run disappea

A     #I_TRIGGER; // Trigger
L     #I_PT; // Setpoint
SE    T [#Timer_No]; // Extended Pulse Timer
A     #I_TIMER_RESET; // RESET
R     T [#Timer_No];
A     T [#Timer_No];
=     #RET_VAL; // Return Timer State
SAVE  ; // Return as ENO as well
BE    ;
NETWORK
TITLE =Check if On-Delay Selected

ODT:  AN    #I_ODT;
JC    ODTS;
NETWORK
TITLE =Line Control: Air Wipes Off Delay when line jog fed/run disappea

A     #I_TRIGGER; // Trigger
L     #I_PT; // Setpoint
SD    T [#Timer_No]; // On-Delay Timer
A     #I_TIMER_RESET; // RESET
R     T [#Timer_No];
A     T [#Timer_No];
=     #RET_VAL; // Return Timer State
SAVE  ; // Return as ENO as well
BE    ;
NETWORK
TITLE =Check if On-Delay Selected

ODTS: AN    #I_ODTS;
JC    OFFD;
NETWORK
TITLE =Line Control: Air Wipes Off Delay when line jog fed/run disappea

A     #I_TRIGGER; // Trigger
L     #I_PT; // Setpoint
SS    T [#Timer_No]; // Retentive On-Delay
A     #I_TIMER_RESET; // RESET
R     T [#Timer_No];
A     T [#Timer_No];
=     #RET_VAL; // Return Timer State
SAVE  ; // Return as ENO as well
BE    ;
NETWORK
TITLE =Check if Off-Delay Selected

OFFD: AN    #I_OFFDT;
JC    NONE;
NETWORK
TITLE =Line Control: Air Wipes Off Delay when line jog fed/run disappea

A     #I_TRIGGER; // Trigger
L     #I_PT; // Setpoint
SF    T [#Timer_No]; // Retentive On-Delay
A     #I_TIMER_RESET; // RESET
R     T [#Timer_No];
A     T [#Timer_No];
=     #RET_VAL; // Return Timer State
SAVE  ; // Return as ENO as well
BE    ;
NETWORK
TITLE =Error - return False & ENO=0

NONE: CLR   ;
=     #RET_VAL;
SAVE  ;
END_FUNCTION