This is SCL code that works for finding the size of a DB.  Perhaps you can adjust it to work with just the array.  Works with S7-1200 on V13 with FW 3.0/4.0/4.1

FUNCTION_BLOCK "Get_DB_Size"
TITLE =  Get a DB's Size
{ S7_Optimized_Access := 'TRUE' }
AUTHOR : DHuggins
VERSION : 0.1
//Return DB size using ENO to generate fault when PEEK beyond DB bounds (per Siemens Support) -- NOTE : just for s7-1200 
   VAR_INPUT DB_SPECIFIC
      db_Num : UInt;
   END_VAR

   VAR_OUTPUT
      Size : UInt;   // default db size=0
   END_VAR

   VAR
      db_index : UInt;
      db_byte : Byte;
      trapped_error {OriginalPartName := 'ErrorStruct'; LibVersion := '1.0'} : ErrorStruct;
   END_VAR

   VAR_TEMP
      max_index : UInt;
      err_id : Word;
   END_VAR

BEGIN
 //-------------------------------------------------------------------
 #db_index := 0;      // initialize
 #max_index := 1000;  // set a constraint to prevent watchdog timeouts
 
 
 //===================================================================
 // not strictly required to handle errors internally
 // but if a FW or service pack or update suddenly causes errors,
 // this should prevent cpu crashes
 // ==================================================================
 //
 // clear out any existing error conditions
 //
 
 #err_id := GET_ERR_ID();
 
 REPEAT
   ENO := true;  // why would this be needed?  it seems it is required though
   #db_byte := PEEK(area:=16#84, dbNumber:=#db_Num, byteOffset:=#db_index);
   #db_index := #db_index + 1; 
 UNTIL (#db_index >= #max_index) OR (NOT ENO) END_REPEAT;
 
 IF NOT ENO THEN
   #Size := #db_index-1;  // copy count when ENO went off (before inc(1) )
 ELSE
   #Size := 0;            // DB does not exist or is very large
 END_IF;
 
 RETURN;
 
END_FUNCTION_BLOCK

Ladja

Hello guys,

I've got a question about finding out the size or length of an array in SCL which i defined in Global DB. As i defined it i know the size but i mean i'd like to know if there is any option how to find it by SCL code. Can someone help me?

 I have a SIMATIC S7-1200 CPU and TIA Portal 13

Thank you

Ladja

enof

Some obscure documentation do mention an instruction CountOfElements(variant) which suggests Siemens is making a new innovation which will shock the world.

Please try and let know the results. I'm not able to get it running but didn't try very hard. (I don't like underdocumented stuff)

The CountOfElements  instruction does work.
Maybe the problem lies with the documentation of using the VARIANT type.

- Create an FC / FB in SCL language.
- As IN-OUT parameter you have a variable (ex. myVariant) declared as VARIANT type
- Use the instruction inside the code block using the variable (#myVariant).

#size := CountOfElements(IN:=#myVariant);

See also some example usage:
https://support.industry.siemens.com/tf/ww/de/posts/140246/

CountOfElements is s7-1500 only.  Only thing to do is to trick portal into loop through the array until it goes outside the bounds and trigger an error (ENO toggles off on error), and detect it, grab the count.

William_B

enof

Some obscure documentation do mention an instruction CountOfElements(variant) which suggests Siemens is making a new innovation which will shock the world.

Please try and let know the results. I'm not able to get it running but didn't try very hard. (I don't like underdocumented stuff)

The CountOfElements  instruction does work.
Maybe the problem lies with the documentation of using the VARIANT type.

#size := CountOfElements(IN:=#myVariant);

See also some example usage:
https://support.industry.siemens.com/tf/ww/de/posts/140246/

huggy_d1

CountOfElements is s7-1500 only.  Only thing to do is to trick portal into loop through the array until it goes outside the bounds and trigger an error (ENO toggles off on error), and detect it, grab the count.

My good friend,

What works in the simulator should (close to always) work on the PLC.
The reverse is not true.. thinking of PTO for example.

Attached is a simulation of the current generation PLC.
It is the S7-1200 CPU1214 FW4.1 under TIA Portal V13.1.6.

Siemens made changes for us on the S7-1200 to give us with
more functions related to VARIANT (pointer) data type.

Regards,
w