Sub ShowPropertiesDynamicsofAllObjects()

'VBA483

Dim objObject As HMIObject

Dim colObjects As HMIObjects

Dim colProperties As HMIProperties

Dim objProperty As HMIProperty

Dim strOutput As String

Set colObjects = Application.ActiveDocument.HMIObjects

For Each objObject In colObjects

Set colProperties = objObject.Properties

For Each objProperty In colProperties

If 0 <> objProperty.DynamicStateType Then

strOutput = strOutput & vbCrLf & objObject.ObjectName & " - " & objProperty.DisplayName & ": Statetype " & objProperty.Dynamic.DynamicStateType

End If

Next objProperty

Next objObject

MsgBox strOutput

End Sub

However, it is not clear to me how I would then be able to get access to each of the individual tag triggers (each property could have several tags that are used for the trigger) and change the update cycle from "Upon change" to "User cycle 1". Has anyone a complete example tehey could share, or perhaps some more hints on how to do this?

As a side note, the reason that we are having to do this is that we are using Web Navigator and we have found that it sometimes appears to be losing events when the pictures arefirst loaded. About 10% of the time it will lose perhaps 10% of the events. We are planning on changing to the update cycle to attempt to correct this problem. Has anyone elseexperienced similar problems?

Thanks,

Dan

Thank you Ikkezelf.

What I needed was some way to read the values for the triggers, and from thatI can modify them quite easily. I have created the following script which will print out a listing of all of the trigger information for the objects inthe current PDL file. In addition, I have set this up so that it modifies the trigger cycles for all of the VBscript and Dynamic Dialog based triggers from their current value to "User Cycle 1".

It is a simple matter to change the trigger CycleTime now that I have found how to access it. (I could not find information on this in the documentation.) This script works for the trigger cases that we use, including VBscript, Dynamic Dialog and Direct, although in the example here I have not bothered to change the Direct triggers. In addition to changing the trigger cycles, it will produce a file of the same name as the current PDL file, but with a .TXT extension.

Sub SetDynamicTriggerTimeOfAllObjects()

Dim objObject As HMIObject
Dim colObjects As HMIObjects
Dim colProperties As HMIProperties
Dim objProperty As HMIProperty
Dim strOutput As String
Dim strFileName As String
Dim objScript As HMIScriptInfo
Dim indItem As Long

Set colObjects = Application.ActiveDocument.HMIObjects

strFileName = Application.ActiveDocument.Name
strFileName = "C:\temp\" & Left(strFileName, InStr(1, strFileName, ".")) & "TXT"
Open strFileName For Output As #1

For Each objObject In colObjects
Set colProperties = objObject.Properties
For Each objProperty In colProperties
'
' For each object property check to see if there are any dynamics associated with the property
'
If objProperty.DynamicStateType <> 0 Then

strOutput = objObject.ObjectName & " - " & objProperty.DisplayName
strOutput = strOutput & ": Statetype " & objProperty.DynamicStateType
Print #1, strOutput
'
' Type 4 is dynamic dialog
' Type 3 is script based
'
If objProperty.DynamicStateType = 3 Or objProperty.DynamicStateType = 4 Then
Set objScript = objProperty.Dynamic

For indItem = 1 To objScript.Trigger.VariableTriggers.Count
strOutput = " Tag: " & objScript.Trigger.VariableTriggers.Item(indItem).VarName
Print #1, strOutput
strOutput = " CycleName: " & objScript.Trigger.VariableTriggers.Item(indItem).CycleName
Print #1, strOutput
objScript.Trigger.VariableTriggers.Item(indItem).CycleType = hmiVariableCycleTypeUserCycle1
strOutput = " CycleType: " & objScript.Trigger.VariableTriggers.Item(indItem).CycleType
Print #1, strOutput
strOutput = " CycleTime: " & objScript.Trigger.VariableTriggers.Item(indItem).CycleTime
Print #1, strOutput
Next indItem
Else
Print #1, " Tag: " & objProperty.Dynamic.VarName
Print #1, " CycleName: " & objProperty.Dynamic.CycleName
Print #1, " CycleType: " & objProperty.Dynamic.CycleType

End If
End If

Next objProperty

Next objObject

Close #1

End Sub

Attached is 2 scripts that we use to change all dynamic triggers for a selected set of pdl's, based on the tagname of the trigger variable. We use it to change the trigger cycles to 1 of the 5 UserCycles.

1. Dynamic Dialog
2. C-action
3. VBS Action
4. Tag

use: In VBA editor in Wincc Graphics editor, select project tree, Right mouse click: Import File.

• set the strings that will refuse a pdl filename. module: TriggerCycleFiles.bas: