FRS2010

50ms ispulse durationprogrammed intothe flowmeter

can i have sample program for this subject. Pulse output to flow rate?

Need it badly. Thanks 

Hi

Let's assume Your pulses are right i.e. not too frequent for normal PLC inputs.

if they are too frequent (i.e. time between pulses shorter than PLC scan time + i/q processing time)

you need high speed counter card.

if You need integrator of mass flow You need use double integer or 64-bit integer or 64-bit real data type for mass integration (library can be found on this forum. search for 64-bit real library)

for flow rate measurement:

1. Assume a pulse is xxx kg (constant)

2. uou can use function to get Tick Count and uise it on every raising edge of the pulse

3. if new tick count is lower than old one roll-over occured (this happens every 21 days of runtime)

    add long real full scale to the negative difference

4. all the above gives you time between pulses in ms

5. the time and flow per pulse can be used to calculate Flow: 

    Flow [kg/hr]:=3600000*Kg_Per_Pulse [kg] / Time [ms]

Code [FC]:

//---- BEGINNING OF FC BLOCK

1. Variables:

IN:

I_PULSE : Bool; // INPUT: Pulses from Flow Meter

I_PULSE_KG: Real; // INPUT: Flow in kg per pulse [kg]

I_TICK_COUNT : Time; // Tick Count (update it in every OB1 scan) [ms]

IN/OUT:

IQ_FP_I_PULSE: Bool; // Edge Detection - link variable to STAT / Marker / DB

IQ_PREV_TICK_COUNT: Time; // Previous Tick Count - link to STAT / Marker / DB [ms]

IQ_FLOW : Real // Flow in kg/hr from last pulse (link this to STAT / DB / Marker Variable!) [kg/hour]

RET VAL:

RET_VAL : Bool; // One Scan Pulse when Flow Updated

CODE:

NW1: Check for Pulse

A I_PULSE // Pulse from meter

FP IQ_FP_I_PULSE // Raising Edge

= RET_VAL // Give it to Ret_Val

JCN ENDE // No Edge - Jump to End

NW2: New Pulse - Calculate Time

L I_TICK_COUNT // Current Tick Count

L IQ_PREV_TICK_COUNT // Previous Tick Count

-D // Calculate Time [ms]

L L#0 // 0.0

>D // Calculated Time>=0?

POP // Result back to ACC1 after comparison

JC TCPS // Is Calculated Time>=0? YES: Skip Correction

L     L#2147483647                // NO: Correct Time when calculated time<0

+D                                //       which means Tick Count Re-started in the meantime

TCPS: DTR // Convert Calculated Time to Real

L I_PULSE_KG // Mass Flow per Pulse [kg]

TAK // Toggle Accumulators because calculating Flow = kg/Time

/R // Calculate Flow in kg/ms

L 3600000.0 // Conversion Factor kg/ms --> kg/hour

*R // Convert from kg/ms to kg/hour

T IQ_FLOW //  Return calculated Flow [kg/hour]

L I_TICK_COUNT // Current Tick Count

T IQ_PREV_TICK_COUNT // Store it in Previous Tick Count

ENDE: NW3: ENO:=1;

SET

SAVE

//----END OF FC BLOCK

//---- TICK COUNT - in OB1

Tick Count can be obtained by calling SFC64 at beginning of OB1:

      CALL  "TIME_TCK"
       RET_VAL:="GLOBAL".CLOCK.TICK_COUNT // Tick Count [ms]

//---- how to use

CALL FLOW // Flow Calculation Call

    I_PULSE:=I0.0 // Change to address where input from flow meter is connected

    I_PULSE_KG:=10.0 // Change to flow per pulse [kg/pulse]

    I_TICK_COUNT:="GLOBAL".CLOCK.TICK_COUNT // Tick Count [ms]

    IQ_PREV_TICK_COUNT:=MD4 // Previous Tick Count - Marker or STAT or DB

    IQ_FLOW:=MD8 // Calculated Flow [kg/hr] - Marker or STAT or DB

    RET_VAL:=M0.1 // This is one-shot pulse issued every time flow is updated.

Note: in LAD the ENO output is always True.

Hi,

Thanks for this nice code that I gonna use in my program!

However, if I am not mistaken, at the end of NW2, you need to:

L I_TICK_COUNT // Current Tick Count

T  IQ_PREV_TICK_COUNT // Previous Tick Count

Am I wrong?