FUNCTION "MEMCMP" : Bool

TITLE = 'Memory Compare'

{ S7_Optimized_Access := 'FALSE' }

AUTHOR : Smiffy

VERSION : 0.2

VAR_INPUT

IN1 : Any;

IN2 : Any;

END_VAR

VAR_TEMP

RetVal : Int;

IN1End : DInt;   // End addresses for memory areas

IN2End : DInt;   // End addresses for memory areas

Tst1 : Byte;

Tst2 : Byte;

MemPtr : DInt;   // Current memory pointer

pIN1 : Any;   // DB address ANY pointer - used for accessing DB data

pAnyIN1 AT pIN1 : Struct   // Diassembled ANY pointer structure

S7Code : Byte;   // Code for S7 (fixed at 16#10)

DataType : Byte;   // Code for data type

Length : Int;   // Repetition factor = Send/receive length

DBNumber : Int;   // Data block Number

MemoryArea : Byte;   // Specified memory area = 0x84 = data block

ByteAddressMSB : Byte;   // Byte address most significant bits

ByteAddressLSB : Word;   // Byte address least significant bits

END_STRUCT;

u1Addr : DInt;   // Union pointer for calculation of byte offset address

u1 AT u1Addr : Struct   // This is equivalent to a union in 'c' dword goes in and word / byte LSB / byte MSB come out

ByteAddrLSBPad : Byte;   // Not Used

ByteAddrMSB : Byte;   // Byte address most significant bits

WordAddr : Word;   // Byte address least significant bits

END_STRUCT;

pIN2 : Any;   // DB address ANY pointer - used for accessing DB data

pAnyIN2 AT pIN2 : Struct   // Diassembled ANY pointer structure

S7Code : Byte;   // Code for S7 (fixed at 16#10)

DataType : Byte;   // Code for data type

Length : Int;   // Repetition factor = Send/receive length

DBNumber : Int;   // Data block Number

MemoryArea : Byte;   // Specified memory area = 0x84 = data block

ByteAddressMSB : Byte;   // Byte address most significant bits

ByteAddressLSB : Word;   // Byte address least significant bits

END_STRUCT;

u2Addr : DInt;   // Union pointer for calculation of byte offset address

u2 AT u2Addr : Struct   // This is equivalent to a union in 'c' dword goes in and word / byte LSB / byte MSB come out

ByteAddrLSBPad : Byte;   // Not Used

ByteAddrMSB : Byte;   // Byte address most significant bits

WordAddr : Word;   // Byte address least significant bits

END_STRUCT;

END_VAR

BEGIN

//ZHK: init added

#MEMCMP := FALSE;

#u1Addr := 0;

#u2Addr := 0;

#pIN1 := #IN1;

#pAnyIN1.DataType := 16#02;

#u1.ByteAddrMSB := #pAnyIN1.ByteAddressMSB;

#u1.WordAddr := #pAnyIN1.ByteAddressLSB;

#IN1End := #u1Addr + (#pAnyIN1.Length * DINT#8); // ZHK: DINT#8 instead of 8 to exclude INT overflow

#pAnyIN1.Length := 1;

#pIN2 := #IN2;

#pAnyIN2.DataType := 16#02;

#u2.ByteAddrMSB := #pAnyIN2.ByteAddressMSB;

#u2.WordAddr := #pAnyIN2.ByteAddressLSB;

#IN2End := #u2Addr + (#pAnyIN2.Length * DINT#8);

#pAnyIN2.Length := 1;

WHILE (#u1Addr < #IN1End) AND (#u2Addr < #IN2End) DO

#RetVal := BLKMOV(SRCBLK := #pIN1, DSTBLK => #Tst1);

IF #RetVal <> 0 THEN

#MEMCMP := FALSE;

RETURN;

END_IF;

#RetVal := BLKMOV(SRCBLK := #pIN2, DSTBLK => #Tst2);

IF #RetVal <> 0 THEN

#MEMCMP := FALSE;

RETURN;

END_IF;

IF #Tst1 <> #Tst2 THEN

#MEMCMP := FALSE;

RETURN;

END_IF;

#u1Addr := #u1Addr + 8;

#pAnyIN1.ByteAddressMSB := #u1.ByteAddrMSB;

#pAnyIN1.ByteAddressLSB := #u1.WordAddr;

#u2Addr := #u2Addr + 8;

#pAnyIN2.ByteAddressMSB := #u2.ByteAddrMSB;

#pAnyIN2.ByteAddressLSB := #u2.WordAddr;

END_WHILE;

#MEMCMP := TRUE;

END_FUNCTION