Hi there,

I'm migrating my project form an S7-1500 to an S7-1200.

I made a program block (on the S7-1500) that generates a random number using the TIME_TCK():

When I compile this FB on my S7-1200 I get this error "Block 'TIME_TCK' is not supported by the CPU or library version you are using."

How can I replace the TIME_TCK()?

Thanks for the help!

fedex03

How can I replace the TIME_TCK()?

I am using a TON timer with autorestart after long timeout, capturing the elapsed time instead of the time_tick() function.

Towome

Hi,

use LGF function LGF_RandomRange_Real.

Library of general functions (LGF) for SIMATIC STEP 7 (TIA Portal) and SIMATIC S7-1200 / S7-1500

Regards,

Towome

Hi Towome,

thank you for the library, it will be very useful also in the future.

I made a network (I attached it) that simulates the temperature of a motor (and round it at two decimal digits).

Since the real is always greater then 0, how can I make the random number also negative?

Otherwise, the motor temperature will increase forever.

If my random number will be negative (sometimes) I can obtain temperature around a starting point.

Thank you,

Federico

fedex03

I made a network (I attached it) that simulates the temperature of a motor (and round it at two decimal digits).

Omme, povera me!

Your temperature model it's less than poor. It's simply wrong! You forget the basic physics rules here.

Thi following code it's simple but usefull for your pourpuse:

FUNCTION_BLOCK "HeatingBarModel"
TITLE = HeatingBarModel
{ S7_Optimized_Access := 'TRUE' }
AUTHOR : 'B.M.'
FAMILY : QuickThermoregulator
VERSION : 0.3
//2023/06/03
//- Migliorato il codice con un modello più coerente con la realtà.
//2023/06/04
//- Migliorato il codice con ulteriori parametri di ingresso per descrivere il modello più coerente con la realtà.
VAR_INPUT
r_in_power : Real;
r_in_ambient_temperature : Real;   // Temperatura ambiente
x_init : Bool;
k_accum_a : Real;   // Proportional to the dimension of the bar around the heater
r_k_migration_a_b : Real;
k_accum_b : Real;   // Proportional to the dimension of the bar around the feedback sensor
r_k_dissipation_b_air : Real;
k_energia_temperatura_b : Real;   // Coefficiente energia / temperatura
END_VAR

VAR_OUTPUT
r_out_temperature : Real;
END_VAR

VAR
r_energy_accum_a : Real;   // Energia accumulata al punto di ingresso
r_energy_accum_b : Real;   // Energia accumulata al punto di misura
t_acc1 : Time;
END_VAR

VAR_TEMP
t_last : Time;
r_k : Real;
END_VAR


BEGIN
IF #x_init THEN
#t_acc1 := "Millis"(t#0ms);
#r_energy_accum_a := #r_out_temperature / #k_energia_temperatura_b;
#r_energy_accum_b := #r_out_temperature / #k_energia_temperatura_b;
#r_out_temperature := #r_in_ambient_temperature;
RETURN;
END_IF;

#t_last := "Millis"(#t_acc1);
#t_acc1 := "Millis"(t#0ms);

// Energia accumulata al punto di riscaldamento (a)
#r_energy_accum_a := #r_energy_accum_a + (#r_in_power * #k_accum_a * DINT_TO_REAL(TIME_TO_DINT(#t_last)) / 1000.0);

// Energia migrante da (a) verso (b)
#r_k := ((#r_energy_accum_a - #r_energy_accum_b) * (DINT_TO_REAL(TIME_TO_DINT(#t_last))) / (1000.0 * #r_k_migration_a_b));
// Energia accumulata in (b)
#r_energy_accum_b := #r_energy_accum_b + (#r_k * #k_accum_b);
// Energia persa in (a)
#r_energy_accum_a := #r_energy_accum_a - #r_k;

// Scambio con ambiente (c)
// differenza di temperatura
#r_k := #r_out_temperature - #r_in_ambient_temperature;
// Energia dissipata
#r_k := #r_k * #r_k_dissipation_b_air;

// Perdita di energia equivalente punto (b)
// Energia persa verso l'ambiente
#r_energy_accum_b := #r_energy_accum_b - (#r_k * (DINT_TO_REAL(TIME_TO_DINT(#t_last)) / 1000.0));
// Temperatura interna finale
#r_out_temperature := #r_energy_accum_b * #k_energia_temperatura_b;

RETURN;
END_FUNCTION_BLOCK


 

Mauro.Bottizzo

fedex03

I made a network (I attached it) that simulates the temperature of a motor (and round it at two decimal digits).

Omme, povera me!

Your temperature model it's less than poor. It's simply wrong! You forget the basic physics rules here.

Thi following code it's simple but usefull for your pourpuse:

 

FUNCTION_BLOCK "HeatingBarModel"
TITLE = HeatingBarModel
{ S7_Optimized_Access := 'TRUE' }
AUTHOR : 'B.M.'
FAMILY : QuickThermoregulator
VERSION : 0.3
//2023/06/03
//- Migliorato il codice con un modello più coerente con la realtà.
//2023/06/04
//- Migliorato il codice con ulteriori parametri di ingresso per descrivere il modello più coerente con la realtà.
VAR_INPUT
r_in_power : Real;
r_in_ambient_temperature : Real;   // Temperatura ambiente
x_init : Bool;
k_accum_a : Real;   // Proportional to the dimension of the bar around the heater
r_k_migration_a_b : Real;
k_accum_b : Real;   // Proportional to the dimension of the bar around the feedback sensor
r_k_dissipation_b_air : Real;
k_energia_temperatura_b : Real;   // Coefficiente energia / temperatura
END_VAR

VAR_OUTPUT
r_out_temperature : Real;
END_VAR

VAR
r_energy_accum_a : Real;   // Energia accumulata al punto di ingresso
r_energy_accum_b : Real;   // Energia accumulata al punto di misura
t_acc1 : Time;
END_VAR

VAR_TEMP
t_last : Time;
r_k : Real;
END_VAR


BEGIN
IF #x_init THEN
#t_acc1 := "Millis"(t#0ms);
#r_energy_accum_a := #r_out_temperature / #k_energia_temperatura_b;
#r_energy_accum_b := #r_out_temperature / #k_energia_temperatura_b;
#r_out_temperature := #r_in_ambient_temperature;
RETURN;
END_IF;

#t_last := "Millis"(#t_acc1);
#t_acc1 := "Millis"(t#0ms);

// Energia accumulata al punto di riscaldamento (a)
#r_energy_accum_a := #r_energy_accum_a + (#r_in_power * #k_accum_a * DINT_TO_REAL(TIME_TO_DINT(#t_last)) / 1000.0);

// Energia migrante da (a) verso (b)
#r_k := ((#r_energy_accum_a - #r_energy_accum_b) * (DINT_TO_REAL(TIME_TO_DINT(#t_last))) / (1000.0 * #r_k_migration_a_b));
// Energia accumulata in (b)
#r_energy_accum_b := #r_energy_accum_b + (#r_k * #k_accum_b);
// Energia persa in (a)
#r_energy_accum_a := #r_energy_accum_a - #r_k;

// Scambio con ambiente (c)
// differenza di temperatura
#r_k := #r_out_temperature - #r_in_ambient_temperature;
// Energia dissipata
#r_k := #r_k * #r_k_dissipation_b_air;

// Perdita di energia equivalente punto (b)
// Energia persa verso l'ambiente
#r_energy_accum_b := #r_energy_accum_b - (#r_k * (DINT_TO_REAL(TIME_TO_DINT(#t_last)) / 1000.0));
// Temperatura interna finale
#r_out_temperature := #r_energy_accum_b * #k_energia_temperatura_b;

RETURN;
END_FUNCTION_BLOCK


 

 

Grazie!

For my pourposes, I need only a random value in a specific range.

But thank you for your example! I'll use it.