average of last 30 sample of same analog input

Dear sir

How can i store last 20 or 30 s sample of same analog input .then average this 30 store sample value .is there any such type of function in siemens plc

with regards

rawat

This is a block a created to archive a value in my case time begin and time end. It was to check the scan time of OB35 over a number of cycles. I am sure you will be able to use this as an example.

FUNCTION_BLOCK "BUFFER SCAN TIMES"
TITLE =
//This block archives the time difference between TIME_END and TIME_BEG. The
//number of data areas depends on the INPUT parameter BUFFERArea_No_of_Samples.
//For example if we use P#DB2.DBX0.0 TIME 10. This block will calculate the time
//difference 10 times and store the values in DB2. Therefore DB2 must contain at
//least 40 bytes of data. Once the number of samples is finished the
//StartBuffering bit is reset.
{ S7_language := '9(1) English (United States)$R$L04.02.2004 15:12:02' }
VERSION : 0.1

VAR_INPUT
BufferArea_No_of_Samples : ANY ;
TM : TIME ;
END_VAR
VAR_IN_OUT
StartBuffering : BOOL ;
END_VAR
VAR
anydata : STRUCT
syntax_ID : BYTE ;//In step7 it is always 16#10
data_type : BYTE ;
data_quantity : INT ;
data_block_number : WORD ;//used for DB's only
area_crossing_pointer : DWORD ;//10000ZZZ00000YYYYYYYYYYYYYYYYXXX
END_STRUCT ;
loopmem : INT ;
working_register : INT ;
old_working_register : INT ;
TIMEEND : "TIME_END";
TM_DIFF : TIME ;
POINTER_MEMORY : DWORD ;
FIRSTRUN : BOOL ;
SAMPLES : INT ;
TM_DIFF_real : REAL ;
END_VAR
VAR_TEMP
POINTER_MEMORY_TEMP : DWORD ;
DataDB : WORD ;
END_VAR
BEGIN
NETWORK
TITLE =
//Find the end time and subtract the begin timr from the end time. If
//startbuffering=1 then go to network 2

CALL #TIMEEND (
TM := #TM,
TM_DIFF := #TM_DIFF);

//AN #StartBuffering
// JC END

NETWORK
TITLE =
//This block will be using Area Crossing type pointer access P#Zx.y e.g.
//P#dbd0
A #FIRSTRUN; //the first time you run the code load the pointer data
JC TEST;

L P##BufferArea_No_of_Samples;
LAR1 ;
L B [AR1,P#0.0];
T #anydata.syntax_ID;
L B [AR1,P#1.0];
T #anydata.data_type;
L W [AR1,P#2.0];
T #anydata.data_quantity; // use this to determine how many samples to take
L 1;
-I ;
T #SAMPLES; //number of samples to save. use with loop counter

L W [AR1,P#4.0];
T #DataDB; // use this to open the datablock required

L D [AR1,P#6.0];
T #anydata.area_crossing_pointer;

//initialize these data areas to zero
L 0;
T #loopmem;
T #old_working_register;
T #working_register;
T #POINTER_MEMORY_TEMP;
T #POINTER_MEMORY;
JU TEST;

NETWORK
TITLE =

TEST: L P##BufferArea_No_of_Samples;
LAR1 ;
L W [AR1,P#4.0];
T #DataDB;

OPN DB [#DataDB];
A #FIRSTRUN;
JC INC;
L #anydata.area_crossing_pointer;
LAR1 ;
SET ;
S #FIRSTRUN;
JU STOR;

INC: L #POINTER_MEMORY;
LAR1 ;
JU STOR;

STOR: L #TM_DIFF;
T DBD [AR1,P#0.0];
DTR ;
T #TM_DIFF_real;
+AR1 P#4.0;
TAR1 #POINTER_MEMORY_TEMP;
L #POINTER_MEMORY_TEMP;
T #POINTER_MEMORY;
L #loopmem;
L #SAMPLES;
>=I ;
R #FIRSTRUN;
R #StartBuffering;
//increment the loop memory by one
L #loopmem;
L 1;
+I ;
T #loopmem;

BE ;
END_FUNCTION_BLOCK