Jerk

Deine Positionieranforderung mit ca. 1mm Genauigkeit bekommst du wahrscheinlich über selbst eine geschriebene Funktion mit Eil/Schleichgang oder Analog prinzipiel hin.
Du kannst aber auch gleich dafür bereits vorgesehen Module wie ET200S 1POS-U oder FM351 verwenden. Da hast du dann die Geberanbindung auch schon drin.

Dennoch möchte ich das Thema mit EMC von IBN-Service noch mal richtig stellen:

@@@@@@@@@@@@@@@@@@@@@@
mal kurz überschlagen:

3.8 m/min = 63.33 mm/s

Geschätze Zykluszeit 20 ms.

Fahrweg über 2 SPS - Zyklen (durchschnittliche Reaktionszeit):

ca. 2.5mm.

Da hift dann auch kein EMC (für 400 Euro?), mit der Geschwindigkeit
und der geschätzten Zykluszeit kannst du mit einer einfachen
Abschaltpositionierung nicht auf 1mm genau positionieren.
@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

EMC ist eine Lageregelung und keine Abschaltpositionierung!!!

Deshalb stimmt die Rechnung vin IBN-Service so nicht.
Mit EMC kann man egal bei welcher Geschwindigkeit und und von mir aus mit einem OB35 Takt (Lageregleraufruf) von 20ms (um den OB1 nicht ständig zu stark auszubremsen) mit einem Frequenzumrichter als Antiebsteller bis auf <0.1 mm genau fahren,.
Hängt natürlich stark von übliche Faktoren wieMechanik, Geberauflösung, Getriebübersetzung etc. ab.


Gruß
Jerk

ich will dich mal rügen:

Bevor du dem Fragesteller Hardware empfiehlst,
solltest du erst mal sicherstellen, ob das von Ihm
eingesetzte Absolutmesssystem überhaupt einSSI Geber ist.

Die 351 unterstützt nämlich auch nur:

symetrische und asymetrische Inkrementalgeber
sowie
SSI - Absolutgeber.

Im Weiteren sprach ich explizit von "einfacher Abschaltpositionierung".
Vielleicht habe ich mich da unklar ausgedrückt.

Aber auch für eine analoge Lageregelung benötige ich kein EMC.

EMC ist was für Leute, die lieber parametrieren
als programmieren oder nicht gut programmieren können,
was auf dich ja durchaus zutreffen mag.

Daher hat natürlich auch EMC seine Existenzberechtigung,
aber mit der letztendlich erreichbaren Genauigkeit hat das
nichts zu tun.

Das mit dem verallgemeinertem EMC = 0.1mm von dir ist
natürlich völliger Blödsinn.

Du relativierst dass dann ja auch selber mit dem Spruch
"Hängt natürlich stark von übliche Faktoren ab..."

Also nichts als BlaBla...

Prinzipiell empfehle ich dir,

Beiträge erst mal genau durchzulesen bevor du darauf
zu antworten versuchst.

Wenn du aber nur trollen willst,
da gibt es ganz sicher besser geeignete Foren für dich
als das SIMATIC - Forum.

In so fern bin ich gespannt auf deine weiteren Beiträge...

Oder sind deine Beiträge bis zum Stromlaufplan geprüft?

Ich denke diese Forum sollte dafür da sein umGegenseitig aus den Erfahrungen anderer zu profitieren. Die Erfahrungen können dabei doch aber durchaus einmal verschieden sein.

Jerk

Was ich mich dennoch Frage, ist ob bei dir Zeit kein Geld kostet, denn wenn er evtl. mit dem Thema noch nicht soviel gemacht hat und es selber programmieren will, vielleicht mit so Standardfunktionen wie frei definierbarer Beschleunigung, Verzögerung, Geschwindigkeit , Überwachungen , evtl. ablösende Bewegungen etc., so sind 400EUR an Zeit auch schnell verbraten.

Sven.Z

Guten Morgen IBN-Service und Jerk,

Ich wollte mich eben für die Ideen bedanken, und werde das jetzt wohl selber lösen, da ich mit Siemens gesprochen hab. Mein problem wäre bei der EMC-Software wirklich die Lizens da ich ungefähr 20. S7-300 Stationen damit ausstatten müsste. Ist dann doch ein bisschen teuer. Aber habe mich dazu durchgerungen das selber zuProgrammieren.
Nochmal kurz zu Eill/ Schleichgang, Also den wert 3,6m/min habe ich im Schleichgang, wie IBN-Service schon sagt ist das zu schnell,ich werde wahrscheinlich ein 3. Parametersatz mit ca. 5Hz brauchen damit es funktioniert. Habe mir dazu auch schon gedanken gemacht die sich schonmal ganz gut anhören ^^ ist nur die frage ob es funktioniert.Najadann werd ichmal mein glück versuchen
aber wie gesagt besten dank für die Ideen.

@ IBN-Service: Also dein Angebot mit dem Pos-Baustein bzw. dem beispiel nehme ich gerne an, vll ist deine Idee ja besser wie meine

MfgSven

Sven.Z

@ IBN-Service: Also dein Angebot mit dem Pos-Baustein bzw. dem beispiel nehme ich gerne an, vll ist deine Idee ja besser wie meine

MfgSven

hier ein einfacher Abschalt - Positionierbaustein mit
3 Drehzahlen, Zielfenster und Zwischenziel als AWL - Quelle.

Ich habe die Kommentare etwas "aufgebohrt" und
die Zwischenergebnisse besonders ausführlich dargestellt,
um die Funktion zu verdeutlichen.
Der Baustein sollte so funktionieren. Ich habe mir aber nicht
die Mühe gemacht, alles nochmals zu testen.

Kurze Erleuterung:

MaxPos und MinPos dient der Eingabe eines
Zwischenzieles, z.B. ein Hinderniss auf dem Weg zum
Endziel. Bei Erreichen dieser Position wird kein
"Ziel erreicht" ausgegeben.

Damit kannst du z.B. den maximalen Gesamtfahrweg begrenzen.

Die Fenster für die verschiedenen Geschwindigkeiten:

Fenster_R1 : Größe für Rampenfenster 1 (mittlere Geschwindigkeit),
sollte das größte Fenster sein, z.B. 500 mm

Fenster_R2 : Größe für Rampenfenster 2 (niedrige Geschwindigkeit),
sollte kleiner als Rampe 1 sein, aber größer als Zielfenster, z.B. 100mm.

Fenster_Ziel : Größe des Toleranzfensters für "Ziel erreicht",
wird dieses Fenster erreicht sollte der Antrieb abschalten und zum
Stillstand kommen, z.B. 1 mm.

Bei der Einstellung der Fenster sollte immer beachtet werden, diese
so groß zu wählen, dass der Antrieb auch sicher auf die niedrigere
Geschwindigkeit abbremsen kann, bevor das nächste Fenster erreicht ist.

Rampe 1 "IN_R1": Wird diese Position erreicht, soll der Antrieb
auf mittlere Geschwindigkeit umschalten.

Rampe 2 "IN_R2": Wird diese Position erreicht, soll der Antrieb
auf niedrigste Geschwindigkeit umschalten.

Ziel erreicht "ZERR": Die Istposition befindet sich innerhalb des
Ziel - Toleranzfensters, der Antrieb kann ausgeschaltet werden.

VOR : Antrieb soll vorwärts fahren.
ZUR : Antrieb soll Rückwärts fahren.

VOR/ZUR ist auch aktiv, wenn das Zielfenster schon erreicht ist
aber nicht die genaue Position getroffen wurde (was meist der Fall ist).

Wenn Probleme auftauchen oder noch Fragen offen sind,
einfach nochmals melden!

[code]

FUNCTION FC 323 : VOID
TITLE =Dreipunkpositionierer REAL mit Kollisionsvermeidung
//Dreipunkpositionierer / Positionssoftwareendschalter
//Geeignet für Antriebe mit 1 oder 2 Drehzahlen und Stellantriebe
//
//Beispiel für mögliche Bedeutung der Rampen :
//
//ZERR IN_R2 IN_R1 VOR ZUR
// X X X X Istposition innerhalb Zielfenster, kleiner SOLL
// X X X X Istposition innerhalb Zielfenster, größer SOLL
// X X X Vorfahren mit kleiner Geschwindigkeit
// X X X Zurückfahren mit kleiner Geschwindigkeit
// X X Vorfahren mit mittlerer Geschwindigkeit
// X X Zurückfahren mit mittlerer Geschwindigkeit
// X Vorfahren mit hoher Geschwindigkeit
// X Zurückfahren mit hoher Geschwindigkeit
AUTHOR : IBNS
FAMILY : POSI
NAME : DREHPOS
VERSION : 0.0

VAR_INPUT
Freig : BOOL ;//Freigabebit, wenn LOW werden alle Ausgangsbits rückgesetzt
SOLL : REAL ;//Sollwert
IST : REAL ;//Istwert
MaxPos : REAL ;//Maximale erlaubte Istposition zur dynamischen Kollisionsvermeidung
MinPos : REAL ;//Minimale erlaubte Istposition zur dynamischen Kollisionsvermeidung
Fenster_R1 : REAL ;//Wert fuer Rampenfenster 1 (mittlere Geschwindigkeit)
Fenster_R2 : REAL ;//Wert fuer Rampenfenster 2 (niedrige Geschwindigkeit)
Fenster_Ziel : REAL ;//Toleranzfenster für "Ziel erreicht"
END_VAR
VAR_OUTPUT
VOR : BOOL ;//Vorwärts fahren (zur höheren Position) / Stellgröße erhöhen
ZUR : BOOL ;//Rückwärts fahren (zur höheren Position) Stellgröße verringern
IN_R1 : BOOL ;//Istwert innerhalb Rampenfenster 1, mittlere Geschwindigkeit angefordert
IN_R2 : BOOL ;//Istwert innerhalb Rampenfenster 2, niedrigste Geschwindigkeit angefordert
ZERR : BOOL ;//Ziel erreicht, Istwert ist innerhalb des Zielfensters
END_VAR
VAR_TEMP
TmpSoll : REAL ;//Zwischenziel für Kollisionshalt
Unt_Rnd_Tol : REAL ;//Unterer Toleranzfensterrand
Ober_Rnd_Tol : REAL ;//Oberer Toleranzfensterrand
Unt_Rnd_Ra2 : REAL ;//Unterer Rampen 2 - Fensterrand
Ober_Rnd_Ra2 : REAL ;//Oberer Rampen 2 - Fensterrand
Unt_Rnd_Ra1 : REAL ;//Unterer Rampen 1 - Fensterrand
Ober_Rnd_Ra1 : REAL ;//Oberer Rampen 1 - Fensterrand
Pos_zu_gross : BOOL ;//Istposition ist oberhalb Sollposition
Pos_zu_klein : BOOL ;//Istposition ist unterhalb Sollposition
Pos_ueber_Zielfenster : BOOL ;//Istposition ist oberhalb dem unteren Zielfensterrand
Pos_unter_Zielfenster : BOOL ;//Istposition ist unterhalb dem oberen Zielfensterrand
Pos_ueber_Rampe2 : BOOL ;//Istposition ist oberhalb dem unteren Rampe 2 - Fensterrand
Pos_unter_Rampe2 : BOOL ;//Istposition ist unterhalb dem unteren Rampe 2 - Fensterrand
Pos_ueber_Rampe1 : BOOL ;//Istposition ist oberhalb dem unteren Rampe 1 - Fensterrand
Pos_unter_Rampe1 : BOOL ;//Istposition ist unterhalb dem unteren Rampe 1 - Fensterrand
END_VAR
BEGIN
NETWORK
TITLE =Dynamische Kollisionsvermeidung

L #SOLL;
T #TmpSoll; // wenn keine Kollisionsgefahr, dann Zwischenziel = Ziel

L #SOLL;
L #MaxPos; // liegt Ziel hinter Kollisionspunkt, dann
<R ; // begrenzen auf MaxPos
SPB temi;
T #TmpSoll;
SPA nwe2;
temi: TAK ;
L #MinPos; // oder begrenzen auf MinPos
>R ;
SPB nwe2;
T #TmpSoll;
nwe2: NOP 0;

NETWORK
TITLE = Fensterränder bestimmen für Toleranzfenster "Ziel erreicht"
//Zielerfassung immer auf Ziel, nicht auf Zwischenziel
L #SOLL;
L #Fenster_Ziel;
-R ;
T #Unt_Rnd_Tol; // Unterer Toleranzfensterrand

L #SOLL;
L #Fenster_Ziel;
+R ;
T #Ober_Rnd_Tol; // Oberer Toleranzfensterrand

NETWORK
TITLE = Fensterränder bestimmen für Rampe 2 - Fenster
//Rampenfenster auch für Zwischenziel bestimmen.
L #TmpSoll;
L #Fenster_R2;
-R ;
T #Unt_Rnd_Ra2; // Unterer Rampen 2 - Fensterrand

L #TmpSoll;
L #Fenster_R2;
+R ;
T #Ober_Rnd_Ra2; // Oberer Rampen 2 - Fensterrand

NETWORK
TITLE = Fensterränder bestimmen für Rampe 1 - Fenster
//Rampenfenster auch für Zwischenziel bestimmen.
L #TmpSoll;
L #Fenster_R1;
-R ;
T #Unt_Rnd_Ra1; // Unterer Rampen 1 Fensterrand

L #TmpSoll;
L #Fenster_R1;
+R ;
T #Ober_Rnd_Ra1; // Oberer Rampen 1 Fensterrand

NETWORK
TITLE = Fahrtrichtung bestimmen vorwärts / rückwärts

L #TmpSoll;
L #IST;
>R ;
= #Pos_zu_klein; // Position zu niedrig
<R ;
= #Pos_zu_gross; // Position zu groß

L #Unt_Rnd_Tol;
>=R ;
= #Pos_ueber_Zielfenster; // Position oberhalb dem unteren "Ziel erreicht" - Fensterrand

TAK ;
L #Ober_Rnd_Tol;
<=R ;
= #Pos_unter_Zielfenster; // Position unterhalb dem oberen "Ziel erreicht" - Fensterrand

NETWORK
TITLE =Positionen bestimmen Rampe 1 / Rampe 2

L #IST;
L #Unt_Rnd_Ra2;
>=R ;
= #Pos_ueber_Rampe2; // Istposition oberhalb unterem Fensterrand R2
TAK ;
L #Ober_Rnd_Ra2;
<=R ;
= #Pos_unter_Rampe2; // Istposition unterhalb oberem Fensterrand R2

TAK ;
L #Unt_Rnd_Ra1;
>=R ;
= #Pos_ueber_Rampe1; // Istposition oberhalb unterem Fensterrand R1
TAK ;
L #Ober_Rnd_Ra1;
<=R ;
= #Pos_unter_Rampe1; // Istposition unterhalb oberem Fensterrand R1
NETWORK
TITLE = Ausgabesignale ermitteln

U #Pos_ueber_Zielfenster; // Istposition befindet sich
U #Pos_unter_Zielfenster; // innerhalb des Toleranzfensters
= #ZERR;

U #Pos_zu_klein; // Istposition ist zu niedrig,
= #VOR; // also vorfahren

U #Pos_zu_gross; // Istposition ist zu hoch,
= #ZUR; // also rückwärts fahren

U #Pos_ueber_Rampe2; // Istposition befindet sich
U #Pos_unter_Rampe2; // innerhalb des Rampenfenster 2
= #IN_R2; // (z.B. geringer Restweg)

U #Pos_ueber_Rampe1; // Istposition befindet sich
U #Pos_unter_Rampe1; // innerhalb des Rampenfenster 1
= #IN_R1; // (z.B. hoeherer Restweg)

NETWORK
TITLE =Keine Ansteuerung, wenn keine Freigabe

UN #Freig; // Wenn keine Freigabe,
R #VOR; // alle Fahrtrichtungsbefehle ruecksetzen!
R #ZUR;

NETWORK
TITLE = Baustein Ende

END_FUNCTION

[/code]

IBN-Service

Die Lizenzkosten für EMC sind abhängig u.a. von Lieferform
und Lizenzart.

Eine Lizenz wird für jedes Programm,
welches man mit EMC ausstattet, fällig.

Also 10 Maschinen = 10 x Lizenz bezahlen.

Dafür hat man sich dann doch schnell selber
eine eigene Positionierbibliothek zusammengestellt
und dabei sicher auch noch einiges über das Programmieren
und Codieren gelernt.

gochtel

Nur eine kurze Anmerkung dazu. Die EMC-Lizenz wird pro CPU, wo EMC eingesetzt wird fällig. Sprich 10 Maschinen in einer CPU = 1 Lizenz.

Sven.Z

Und zwar mein Positinswert vom Encoder besteht aus 2 Doppelwörtern und ich hab ein Addressbereich E/A 256 -261. wie mach ich genau die abfrage? Im Anhang liegt die beschriebung nochmal ein bisschen genauer.
Wäre nett wenn du noch eben kurz eine hilfestellung geben könntest!

Mfg Sven